From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 .../commons-jxpath/commons-jxpath-1.3-r4.ebuild    | 63 ++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 dev-java/commons-jxpath/commons-jxpath-1.3-r4.ebuild

(limited to 'dev-java/commons-jxpath/commons-jxpath-1.3-r4.ebuild')

diff --git a/dev-java/commons-jxpath/commons-jxpath-1.3-r4.ebuild b/dev-java/commons-jxpath/commons-jxpath-1.3-r4.ebuild
new file mode 100644
index 000000000000..bc77ab2d8ed2
--- /dev/null
+++ b/dev-java/commons-jxpath/commons-jxpath-1.3-r4.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="Applies XPath expressions to graphs of objects of all kinds"
+HOMEPAGE="https://commons.apache.org/jxpath/"
+SRC_URI="mirror://apache/commons/jxpath/source/${P}-src.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+S="${WORKDIR}/${P}-src"
+
+CDEPEND="
+	dev-java/jdom:0
+	java-virtuals/servlet-api:3.0
+	dev-java/commons-beanutils:1.7"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.6"
+
+DEPEND="
+	${CDEPEND}
+	test? (
+		dev-java/ant-junit:0
+		dev-java/commons-logging:0
+		dev-java/commons-collections:0
+	)
+	>=virtual/jdk-1.6"
+
+JAVA_ANT_REWRITE_CLASSPATH="yes"
+EANT_GENTOO_CLASSPATH="jdom,servlet-api-3.0,commons-beanutils-1.7"
+
+EANT_TEST_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH},commons-logging,commons-collections,ant-junit"
+ANT_TASKS="ant-junit"
+EANT_TEST_TARGET="test"
+
+src_prepare() {
+	default
+
+	# Don't automatically run tests.
+	sed 's/depends="compile,test"/depends="compile"/' -i build.xml || die
+
+	# This one needs mockrunner. See #259027.
+	rm -v src/test/org/apache/commons/jxpath/servlet/JXPathServletContextTest.java || die
+}
+
+src_test() {
+	java-pkg-2_src_test
+}
+
+src_install() {
+	java-pkg_dojar target/${PN}.jar
+	use doc && java-pkg_dojavadoc dist/docs/api
+	use source && java-pkg_dosrc src/java/*
+}
-- 
cgit v1.2.3