From 3f71901f8c228f4de570abed1831ce3ee425343e Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 8 Sep 2018 10:50:14 +0100
Subject: gentoo resync 08.09.2018

---
 .../commons-daemon/commons-daemon-1.1.0.ebuild     | 58 ++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-java/commons-daemon/commons-daemon-1.1.0.ebuild

(limited to 'dev-java/commons-daemon/commons-daemon-1.1.0.ebuild')

diff --git a/dev-java/commons-daemon/commons-daemon-1.1.0.ebuild b/dev-java/commons-daemon/commons-daemon-1.1.0.ebuild
new file mode 100644
index 000000000000..6949a3798a39
--- /dev/null
+++ b/dev-java/commons-daemon/commons-daemon-1.1.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+JAVA_PKG_IUSE="doc examples source"
+
+inherit autotools java-pkg-2 java-ant-2
+
+DESCRIPTION="Tools to allow Java programs to run as UNIX daemons"
+SRC_URI="mirror://apache/commons/daemon/source/${P}-src.tar.gz"
+HOMEPAGE="https://commons.apache.org/daemon/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="kernel_linux"
+
+CDEPEND="kernel_linux? ( sys-libs/libcap )"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.6"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.6"
+
+S="${WORKDIR}/${P}-src"
+
+src_prepare() {
+	default
+	cd "${S}/src/native/unix" || die
+	sed -i "s/powerpc/powerpc|powerpc64/g" support/apsupport.m4 || die
+	eautoconf
+}
+
+src_configure() {
+	java-ant-2_src_configure
+	cd "${S}/src/native/unix" || die
+	default
+}
+
+src_compile() {
+	java-pkg-2_src_compile
+	cd "${S}/src/native/unix" || die
+	default
+}
+
+src_install() {
+	dobin src/native/unix/jsvc
+	java-pkg_newjar dist/*.jar
+
+	dodoc README RELEASE-NOTES.txt PROPOSAL.html
+	use doc && java-pkg_dohtml -r dist/docs/*
+	use examples && java-pkg_doexamples src/samples
+	use source && java-pkg_dosrc src/main/java/*
+}
-- 
cgit v1.2.3