From b34c45ec12e8676abfa39cddcf3448ac2bee1574 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 30 Nov 2023 17:04:14 +0000
Subject: gentoo auto-resync : 30:11:2023 - 17:04:14

---
 dev-java/bndlib/bndlib-7.0.0.ebuild | 55 +++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 dev-java/bndlib/bndlib-7.0.0.ebuild

(limited to 'dev-java/bndlib/bndlib-7.0.0.ebuild')

diff --git a/dev-java/bndlib/bndlib-7.0.0.ebuild b/dev-java/bndlib/bndlib-7.0.0.ebuild
new file mode 100644
index 000000000000..2e73c25414dd
--- /dev/null
+++ b/dev-java/bndlib/bndlib-7.0.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+MAVEN_ID="biz.aQute.bnd:biz.aQute.bndlib:${PV}"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="bndlib: A Swiss Army Knife for OSGi"
+HOMEPAGE="https://bnd.bndtools.org/"
+SRC_URI="https://github.com/bndtools/bnd/archive/${PV}.tar.gz -> aQute.bnd-${PV}.tar.gz"
+S="${WORKDIR}/bnd-${PV}"
+
+LICENSE="Apache-2.0 EPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+CP_DEPEND="
+	~dev-java/bnd-annotation-${PV}:0
+	~dev-java/bnd-util-${PV}:0
+	~dev-java/libg-${PV}:0
+	dev-java/osgi-annotation:0
+	dev-java/osgi-cmpn:8
+	dev-java/osgi-core:0
+	dev-java/slf4j-api:0
+"
+
+DEPEND="${CP_DEPEND}
+	dev-java/osgi-service-log:0
+	>=virtual/jdk-17:*
+"
+
+RDEPEND="${CP_DEPEND}
+	>=virtual/jre-17:*
+"
+
+JAVA_AUTOMATIC_MODULE_NAME="biz.aQute.bndlib"
+JAVA_CLASSPATH_EXTRA="osgi-service-log"
+JAVA_RESOURCE_DIRS="res"
+JAVA_SRC_DIR="biz.aQute.bndlib/src"
+
+src_prepare() {
+	java-pkg-2_src_prepare
+	mkdir res || die
+
+	# java-pkg-simple wants resources in JAVA_RESOURCE_DIRS
+	mv biz.aQute.bndlib/img	res || die
+	pushd biz.aQute.bndlib/src > /dev/null || die
+		find -type f \
+			! -name '*.java' \
+			| xargs cp --parent -t ../../res || die
+	popd > /dev/null || die
+}
-- 
cgit v1.2.3