From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 dev-games/ode/ode-0.11.1.ebuild | 72 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 dev-games/ode/ode-0.11.1.ebuild

(limited to 'dev-games/ode/ode-0.11.1.ebuild')

diff --git a/dev-games/ode/ode-0.11.1.ebuild b/dev-games/ode/ode-0.11.1.ebuild
new file mode 100644
index 000000000000..b0af397fe523
--- /dev/null
+++ b/dev-games/ode/ode-0.11.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils
+
+DESCRIPTION="Open Dynamics Engine SDK"
+HOMEPAGE="http://ode.org/"
+SRC_URI="mirror://sourceforge/opende/${P}.tar.bz2"
+
+LICENSE="|| ( LGPL-2.1 BSD )"
+SLOT="0"
+KEYWORDS="amd64 x86 ~x86-fbsd"
+IUSE="debug doc double-precision examples gyroscopic static-libs"
+
+RDEPEND="examples? (
+		virtual/opengl
+	)"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	sed -i \
+		-e "s:\$.*/drawstuff/textures:/usr/share/doc/${PF}/examples:" \
+		drawstuff/src/Makefile.in \
+		ode/demo/Makefile.in || die
+}
+
+src_configure() {
+	# use bash (bug #335760)
+	CONFIG_SHELL=/bin/bash \
+	econf \
+		--enable-shared \
+		$(use_enable static-libs static) \
+		$(use_enable debug asserts) \
+		$(use_enable double-precision) \
+		$(use_enable examples demos) \
+		$(use_enable gyroscopic) \
+		$(use_with examples drawstuff X11)
+}
+
+src_compile() {
+	emake
+	if use doc ; then
+		cd ode/doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	DOCS="CHANGELOG.txt README.txt" \
+		default
+	prune_libtool_files
+	if use doc ; then
+		dohtml docs/*
+	fi
+	if use examples; then
+		cd ode/demo
+		exeinto /usr/share/doc/${PF}/examples
+		local f
+		for f in *.c* ; do
+			doexe .libs/${f%.*}
+		done
+		cd ../..
+		doexe drawstuff/dstest/dstest
+		insinto /usr/share/doc/${PF}/examples
+		doins ode/demo/*.{c,cpp,h} \
+			drawstuff/textures/*.ppm \
+			drawstuff/dstest/dstest.cpp \
+			drawstuff/src/{drawstuff.cpp,internal.h,x11.cpp}
+	fi
+}
-- 
cgit v1.2.3