From 948d557b4a61dc14722668b6b11a4cf3cee07b01 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 13 Sep 2019 17:56:30 +0100
Subject: gentoo resync : 13.09.2019

---
 .../freecell-solver-5.6.0-r2.ebuild                | 52 ++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 dev-games/freecell-solver/freecell-solver-5.6.0-r2.ebuild

(limited to 'dev-games/freecell-solver/freecell-solver-5.6.0-r2.ebuild')

diff --git a/dev-games/freecell-solver/freecell-solver-5.6.0-r2.ebuild b/dev-games/freecell-solver/freecell-solver-5.6.0-r2.ebuild
new file mode 100644
index 000000000000..681a115f0356
--- /dev/null
+++ b/dev-games/freecell-solver/freecell-solver-5.6.0-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+inherit cmake-utils python-single-r1
+
+DESCRIPTION="C library for automatically solving Freecell and some other solitaire variants"
+HOMEPAGE="https://fc-solve.shlomifish.org/"
+SRC_URI="https://fc-solve.shlomifish.org/downloads/fc-solve/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="tcmalloc"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/pysol_cards[${PYTHON_USEDEP}]
+	dev-python/random2[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	tcmalloc? ( dev-util/google-perftools )
+"
+DEPEND="${RDEPEND}
+	dev-perl/Path-Tiny
+	dev-perl/Template-Toolkit
+"
+
+DOCS=( README.html )
+
+PATCHES=( "${FILESDIR}/${P}-cmake.patch" )
+
+src_prepare() {
+	sed -i -e "s|share/doc/freecell-solver/|share/doc/${P}|" CMakeLists.txt || die
+
+	python_fix_shebang board_gen
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_STATIC_LIBRARY=OFF
+		-DFCS_BUILD_DOCS=OFF
+		-DFCS_WITH_TEST_SUITE=OFF #requires unpackaged dependencies
+		-DFCS_AVOID_TCMALLOC=$(usex !tcmalloc)
+	)
+
+	cmake-utils_src_configure
+}
-- 
cgit v1.2.3