From d7ed2b01311f15ba54fe8ea872aab7d59ab2b193 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 29 Jan 2021 18:03:51 +0000
Subject: gentoo resync : 29.01.2021

---
 dev-embedded/libftdi/Manifest              |  2 +-
 dev-embedded/libftdi/libftdi-1.5-r2.ebuild | 93 ++++++++++++++++++++++++++++++
 dev-embedded/libftdi/libftdi-1.5.ebuild    | 85 ---------------------------
 3 files changed, 94 insertions(+), 86 deletions(-)
 create mode 100644 dev-embedded/libftdi/libftdi-1.5-r2.ebuild
 delete mode 100644 dev-embedded/libftdi/libftdi-1.5.ebuild

(limited to 'dev-embedded/libftdi')

diff --git a/dev-embedded/libftdi/Manifest b/dev-embedded/libftdi/Manifest
index ebd972ab07f4..08ee651e6ead 100644
--- a/dev-embedded/libftdi/Manifest
+++ b/dev-embedded/libftdi/Manifest
@@ -6,6 +6,6 @@ DIST libftdi1-1.4.tar.bz2 109521 BLAKE2B 4186342afb2a0118c454230a925ccff2ed0aedd
 DIST libftdi1-1.5.tar.bz2 116297 BLAKE2B 460ab93026e14a452e31fcc6930d305638fdc0ed06cb44fb9d50ad8f80199b17057d2f48a27b8295b43b956934289c872a2ef1ddb7f93fa93c6816511ef7607d SHA512 c525b2ab6aff9ef9254971ae7d57f3549a36a36875765c48f947d52532814a2a004de1232389d4fe824a8c8ab84277b08427308573476e1da9b7db83db802f6f
 EBUILD libftdi-0.20-r1.ebuild 1860 BLAKE2B 5de2b3938e0dff3de2f0b716e41a39345efcad64b618183c3f158e4b2948b7c24ec882c6cf0604cdded97d7c85062e3a701bf6623ff2d0fb9ef9be84a0933bd0 SHA512 6c99842f4f98b5d28cbffa4aabfe64d5d814d0500574e29519f4232dc32d2d7d51462b7295ff87c9114a403b881b36386b843fe1526f55512c5116d051d331ea
 EBUILD libftdi-1.4-r1.ebuild 1670 BLAKE2B 7304f2fbcaaa3b66bcaf73b4fa2a58a376b78e6a75f1a280247b1bc360f66369ca65005297bcd5e070edb078105ad15d5657828279a8f001d92468fe9c914545 SHA512 a226e8874e8509f0922733c24f9d2762ec01b0c941f4e68a9635c3be3a24e486e6ea90a588593a1e6a6fc0fab77e564ecd466e5a70539261a26bec07682c7399
-EBUILD libftdi-1.5.ebuild 1834 BLAKE2B 8e933ff0df226eabaa21c6f9c213d1d7c090d7a23db9df9bc8f38804d5ee5e4c149290131afca80fcd25dde2655f1c0c54bf05af46214b1fc29a6794e77bb3a1 SHA512 ba45a1bae1786350447344d063fbe416815e67872d3db13bca9a1df76a86072cded7da636abbe1bc7cca6c4e548acbe55899fc5fbcfe050a9d7e5bf044e6265f
+EBUILD libftdi-1.5-r2.ebuild 2121 BLAKE2B 9f802b5710637a5ef0a7383d4272a76e7e8972a853f7a0409168b8331febb4c3cf2d464c9cb236bbcf550c238d22258dcc5c47b41f25bd78630f86d7d33a74dd SHA512 2965feaff0b9fdbbb90784a398aecd7c7a65bf60a010bb190a979098f3b669e699679281ff7654f329de8bfa16aa54aeadedc41eac61ea3e6777e89cc62427c0
 EBUILD libftdi-9999.ebuild 1783 BLAKE2B 374d00e6b0cf6b62de3a392ff50277652457973ea7a0a98abdcb001f750c18f3efa972b86b7bbf6829afcdc508549adc03c9db6bfa412036cf1854652c4f5ec6 SHA512 be956ace45871628a70e964f622fea6484e495c35300a56b4a318aae7d0d2ce24f7d956508f4c061df3cfe5ea47fecb1d7d0286ec8a49d553aa91bee74e2e7d4
 MISC metadata.xml 317 BLAKE2B 4ff2cf3b9259460d23387c23356cbf63e43d31a1b6f78704c3f918b97c1ac7e5ca87ed027d4dccd063b8b60e00b8f080e73b2f40520da0552fd7302c68b1e6d6 SHA512 21fd21d84f507274617bf8c059517c75dbad08bbbb22b4655cfb7f31c824004881c1f8fc615215af05333e97770ce925f5ac0b580283901032f6c6145ffa1aba
diff --git a/dev-embedded/libftdi/libftdi-1.5-r2.ebuild b/dev-embedded/libftdi/libftdi-1.5-r2.ebuild
new file mode 100644
index 000000000000..198c985d187e
--- /dev/null
+++ b/dev-embedded/libftdi/libftdi-1.5-r2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+inherit cmake python-single-r1
+
+MY_P="${PN}1-${PV}"
+if [[ ${PV} == 9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
+else
+	SRC_URI="https://www.intra2net.com/en/developer/${PN}/download/${MY_P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+DESCRIPTION="Userspace access to FTDI USB interface chips"
+HOMEPAGE="https://www.intra2net.com/en/developer/libftdi/"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="LGPL-2"
+SLOT="1"
+IUSE="cxx doc examples python test tools"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	python? ( dev-lang/swig )"
+RDEPEND="
+	virtual/libusb:1
+	cxx? ( dev-libs/boost )
+	python? ( ${PYTHON_DEPS} )
+	tools? (
+		!<dev-embedded/ftdi_eeprom-1.0
+		dev-libs/confuse:=
+	)"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/boost )
+"
+
+PATCHES=( "${FILESDIR}"/${P}-tests-no-cxx.patch )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DFTDIPP=$(usex cxx)
+		-DDOCUMENTATION=$(usex doc)
+		-DEXAMPLES=$(usex examples)
+		-DPYTHON_BINDINGS=$(usex python)
+		-DBUILD_TESTS=$(usex test)
+		-DFTDI_EEPROM=$(usex tools)
+		-DCMAKE_SKIP_BUILD_RPATH=ON
+		-DSTATICLIBS=OFF
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}/test" || die
+	LD_LIBRARY_PATH="${BUILD_DIR}/src" ./test_libftdi1 -l all || die
+}
+
+src_install() {
+	cmake_src_install
+
+	# Fix up pkgconfig files
+	# bug #766818
+	if use cxx ; then
+		sed -i -e "s/libftdipp1/libftdi1/" "${ED}"/usr/$(get_libdir)/pkgconfig/libftdi1.pc || die
+		sed -i -e "s/libftdi1/libftdipp1/" "${ED}"/usr/$(get_libdir)/pkgconfig/libftdipp1.pc || die
+	fi
+
+	use python && python_optimize
+	dodoc AUTHORS ChangeLog README TODO
+
+	if use doc ; then
+		# Clean up crap man pages. #356369
+		rm -vf "${BUILD_DIR}"/doc/man/man3/_* || die
+
+		doman "${BUILD_DIR}"/doc/man/man3/*
+		dodoc -r "${BUILD_DIR}"/doc/html
+	fi
+
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+}
diff --git a/dev-embedded/libftdi/libftdi-1.5.ebuild b/dev-embedded/libftdi/libftdi-1.5.ebuild
deleted file mode 100644
index cd5cc4c3539f..000000000000
--- a/dev-embedded/libftdi/libftdi-1.5.ebuild
+++ /dev/null
@@ -1,85 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{6..9} )
-inherit cmake python-single-r1
-
-MY_P="${PN}1-${PV}"
-if [[ ${PV} == 9999* ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
-else
-	SRC_URI="https://www.intra2net.com/en/developer/${PN}/download/${MY_P}.tar.bz2"
-	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86"
-fi
-
-DESCRIPTION="Userspace access to FTDI USB interface chips"
-HOMEPAGE="https://www.intra2net.com/en/developer/libftdi/"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="LGPL-2"
-SLOT="1"
-IUSE="cxx doc examples python test tools"
-RESTRICT="!test? ( test )"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-BDEPEND="
-	doc? ( app-doc/doxygen )
-	python? ( dev-lang/swig )"
-RDEPEND="
-	virtual/libusb:1
-	cxx? ( dev-libs/boost )
-	python? ( ${PYTHON_DEPS} )
-	tools? (
-		!<dev-embedded/ftdi_eeprom-1.0
-		dev-libs/confuse:=
-	)"
-DEPEND="${RDEPEND}
-	test? ( dev-libs/boost )
-"
-
-PATCHES=( "${FILESDIR}"/${P}-tests-no-cxx.patch )
-
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DFTDIPP=$(usex cxx)
-		-DDOCUMENTATION=$(usex doc)
-		-DEXAMPLES=$(usex examples)
-		-DPYTHON_BINDINGS=$(usex python)
-		-DBUILD_TESTS=$(usex test)
-		-DFTDI_EEPROM=$(usex tools)
-		-DCMAKE_SKIP_BUILD_RPATH=ON
-		-DSTATICLIBS=OFF
-	)
-	cmake_src_configure
-}
-
-src_test() {
-	cd "${BUILD_DIR}/test" || die
-	./test_libftdi1	-l all || die
-}
-
-src_install() {
-	cmake_src_install
-	use python && python_optimize
-	dodoc AUTHORS ChangeLog README TODO
-
-	if use doc ; then
-		# Clean up crap man pages. #356369
-		rm -vf "${BUILD_DIR}"/doc/man/man3/_* || die
-
-		doman "${BUILD_DIR}"/doc/man/man3/*
-		dodoc -r "${BUILD_DIR}"/doc/html
-	fi
-
-	if use examples ; then
-		docinto examples
-		dodoc examples/*.c
-	fi
-}
-- 
cgit v1.2.3