From 9ab9a2c6661b7cb6bbaeeb3fbdfedd7546b0142f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 31 Mar 2023 22:06:41 +0100
Subject: gentoo auto-resync : 31:03:2023 - 22:06:41

---
 dev-embedded/libftdi/libftdi-1.5-r5.ebuild | 89 ++++++++++++++++++++++++++++++
 1 file changed, 89 insertions(+)
 create mode 100644 dev-embedded/libftdi/libftdi-1.5-r5.ebuild

(limited to 'dev-embedded/libftdi/libftdi-1.5-r5.ebuild')

diff --git a/dev-embedded/libftdi/libftdi-1.5-r5.ebuild b/dev-embedded/libftdi/libftdi-1.5-r5.ebuild
new file mode 100644
index 000000000000..263ee7edc9ea
--- /dev/null
+++ b/dev-embedded/libftdi/libftdi-1.5-r5.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit cmake python-single-r1
+
+MY_P="${PN}1-${PV}"
+if [[ ${PV} == 9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
+else
+	SRC_URI="https://www.intra2net.com/en/developer/${PN}/download/${MY_P}.tar.bz2"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+	PATCHES=(
+		"${FILESDIR}"/${P}-tests-no-cxx.patch
+		"${FILESDIR}"/${P}-cmake-cxx.patch
+	)
+fi
+
+DESCRIPTION="Userspace access to FTDI USB interface chips"
+HOMEPAGE="https://www.intra2net.com/en/developer/libftdi/"
+
+LICENSE="LGPL-2"
+SLOT="1"
+IUSE="cxx doc examples python test tools"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	virtual/libusb:1
+	cxx? ( dev-libs/boost )
+	python? ( ${PYTHON_DEPS} )
+	tools? ( dev-libs/confuse:= )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/boost )
+"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	python? ( dev-lang/swig )
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DFTDIPP=$(usex cxx)
+		-DDOCUMENTATION=$(usex doc)
+		-DEXAMPLES=$(usex examples)
+		-DPYTHON_BINDINGS=$(usex python)
+		-DBUILD_TESTS=$(usex test)
+		-DFTDI_EEPROM=$(usex tools)
+		-DCMAKE_SKIP_BUILD_RPATH=ON
+		-DSTATICLIBS=OFF
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}/test" || die
+	LD_LIBRARY_PATH="${BUILD_DIR}/src" ./test_libftdi1 -l all || die
+}
+
+src_install() {
+	cmake_src_install
+
+	use python && python_optimize
+	dodoc AUTHORS ChangeLog README TODO
+
+	if use doc ; then
+		# Clean up man pages with too generic names. #356369
+		rm -vf "${BUILD_DIR}"/doc/man/man3/_* || die
+
+		doman "${BUILD_DIR}"/doc/man/man3/*
+		dodoc -r "${BUILD_DIR}"/doc/html
+	fi
+
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+}
-- 
cgit v1.2.3