From 1c33e521c460dc40899ce7bc919602b842ce27e2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 5 Mar 2023 23:52:45 +0000
Subject: gentoo auto-resync : 05:03:2023 - 23:52:45

---
 dev-embedded/gputils/gputils-1.5.2.ebuild | 47 +++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-embedded/gputils/gputils-1.5.2.ebuild

(limited to 'dev-embedded/gputils/gputils-1.5.2.ebuild')

diff --git a/dev-embedded/gputils/gputils-1.5.2.ebuild b/dev-embedded/gputils/gputils-1.5.2.ebuild
new file mode 100644
index 000000000000..11fb1036b9e4
--- /dev/null
+++ b/dev-embedded/gputils/gputils-1.5.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs flag-o-matic
+
+DESCRIPTION="Tools including assembler, linker and librarian for PIC microcontrollers"
+HOMEPAGE="https://gputils.sourceforge.io"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="doc"
+
+PATCHES=(
+	"${FILESDIR}"/gputils-1.5.2-fix-invalid-operator.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# bug #369291, bug #818802
+	tc-ld-disable-gold
+
+	# Their configure script tries to do funky things with default
+	# compiler selection.  Force our own defaults instead.
+	tc-export CC
+
+	# LTO currently causes various segfaults in dev-embedded/sdcc
+	# sys-devel/gcc-11.3.0 '-O3 -flto'
+	filter-flags '-flto*'
+
+	local myeconfargs=(
+		$(use_enable doc html-doc)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	use doc && dodoc doc/gputils.pdf
+}
-- 
cgit v1.2.3