From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 dev-embedded/avr-libc/Manifest              |  5 ++
 dev-embedded/avr-libc/avr-libc-2.0.0.ebuild | 78 +++++++++++++++++++++++++++++
 dev-embedded/avr-libc/metadata.xml          | 12 +++++
 3 files changed, 95 insertions(+)
 create mode 100644 dev-embedded/avr-libc/Manifest
 create mode 100644 dev-embedded/avr-libc/avr-libc-2.0.0.ebuild
 create mode 100644 dev-embedded/avr-libc/metadata.xml

(limited to 'dev-embedded/avr-libc')

diff --git a/dev-embedded/avr-libc/Manifest b/dev-embedded/avr-libc/Manifest
new file mode 100644
index 000000000000..e5113a37ea26
--- /dev/null
+++ b/dev-embedded/avr-libc/Manifest
@@ -0,0 +1,5 @@
+DIST avr-libc-2.0.0.tar.bz2 3590893 BLAKE2B cc628f5f55d12c78ca9215e3e37b4a0061feae3c7c19653384b5d789fb6e1c70efe420631bf987379ae5524ec0f65c6df459eaad0fcfb80833cc4732ed5e796b SHA512 fc8d062043d633350dbe05978935dcb8028257a4f1013f246af9658aef0671def19ac11577d1ee9302df68df1b8cf030b22441d96852e185db212263aacabea6
+DIST avr-libc-manpages-2.0.0.tar.bz2 151137 BLAKE2B 7fbaa9c1014e8cf9b4caac723b57f9c24272da458b987ba302730116437bb3a5b49296c6804d857b421e6f71f2c4efda959d278ebcc14aba35fdd44a958dfca8 SHA512 8b4aaa6ae176076171e90e629e0e6142c4c56f9cc4f1640432384276df2f7b457f5137739535b07b9cede9b5b2e564db7fe200203faa4e2d0cd9874432507823
+DIST avr-libc-user-manual-2.0.0.tar.bz2 932920 BLAKE2B d3190af26dbe38719bc78e73de31af1ce69d885b928f48a4fb9ccd145a33f19f71c017253ad16eadc641fc88495c642dd5fd1668c6bebddf7d813f70db01a3f6 SHA512 246180be1f793b46335a49f33028ff59bd7cc06ca3d8627309521801e405e0e1305663a2c0760521467e75732ad513749bf707732b59fb17744e51acda9bb2c6
+EBUILD avr-libc-2.0.0.ebuild 2017 BLAKE2B d04d957bfe9ffe04f95184d7628c84e52772c57790e4a7f903edd7e415cce2bba007f79b9e0a6fa0367bc29484541f59bb3f8e9aac23ba8609563574b2cb940f SHA512 12e157b71ac9eafe9bd9add60ecdf999f5af83ae24657265751f1b5e0b8e9e4270c4e806e8bbc8da800645de25b8ebf62d6dedbed7e1e45944b20e60a23db26c
+MISC metadata.xml 470 BLAKE2B 8855ba12ec2147f31efb154d314b9e2e625076453bc4ddf43022b08a597a1f1ea5bb401768e38b000718b200b8e60d16214a89c1642b66d31386152e242a4e03 SHA512 0a09da72e78c945fa53ee056913bc563897dcb65c33e8cba04dfd15d57a1578a502f18071b0a3cd5feecdbc7e570bfddfde05deda12746e70962b841d90d566a
diff --git a/dev-embedded/avr-libc/avr-libc-2.0.0.ebuild b/dev-embedded/avr-libc/avr-libc-2.0.0.ebuild
new file mode 100644
index 000000000000..79b7f1163fc2
--- /dev/null
+++ b/dev-embedded/avr-libc/avr-libc-2.0.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+CHOST="avr"
+CTARGET="avr"
+
+inherit flag-o-matic eutils
+
+DESCRIPTION="C library for Atmel AVR microcontrollers"
+HOMEPAGE="http://www.nongnu.org/avr-libc/"
+SRC_URI="https://savannah.nongnu.org/download/avr-libc/${P}.tar.bz2
+	https://savannah.nongnu.org/download/avr-libc/${PN}-manpages-${PV}.tar.bz2
+	doc? ( https://savannah.nongnu.org/download/avr-libc/${PN}-user-manual-${PV}.tar.bz2 )"
+
+LICENSE="BSD"
+SLOT="0"
+# 'amd64' is a blessed placeholder for crossdev. It could
+# be any other arch. See bug #620316#c5
+# Don't add more arches to KEYWORDS.
+KEYWORDS="amd64"
+IUSE="doc headers-only"
+
+DEPEND=">=sys-devel/crossdev-0.9.1"
+[[ ${CATEGORY/cross-} != ${CATEGORY} ]] \
+	&& RDEPEND="!dev-embedded/avr-libc" \
+	|| RDEPEND=""
+
+DOCS="AUTHORS ChangeLog* NEWS README"
+
+pkg_setup() {
+	# check for avr-gcc, bug #134738
+	ebegin "Checking for avr-gcc"
+	if type -p avr-gcc > /dev/null ; then
+		eend 0
+	else
+		eend 1
+
+		eerror
+		eerror "Failed to locate 'avr-gcc' in \$PATH. You can install an AVR toolchain using:"
+		eerror "  $ crossdev -t avr"
+		eerror
+		die "AVR toolchain not found"
+	fi
+}
+
+src_prepare() {
+	epatch_user #455828
+
+	# work around broken gcc versions PR45261
+	local mcu
+	for mcu in $(sed -r -n '/CHECK_AVR_DEVICE/{s:.*[(](.*)[)]:\1:;p}' configure.ac) ; do
+		if avr-gcc -E - -mmcu=${mcu} <<<"" |& grep -q 'unknown MCU' ; then
+			sed -i "/HAS_${mcu}=yes/s:yes:no:" configure
+		fi
+	done
+
+	# Install docs in correct directory
+	sed -i -e "/DOC_INST_DIR/s:\$(VERSION):${PVR}:" configure || die
+
+	strip-flags
+	strip-unsupported-flags
+}
+
+src_install() {
+	default
+
+	# man pages can not go into standard locations
+	# as they would then overwrite libc man pages
+	insinto /usr/share/doc/${PF}/man/man3
+	doins "${WORKDIR}"/man/man3/*
+
+	use doc	&& dohtml "${WORKDIR}"/${PN}-user-manual-${PV}/*
+
+	# Make sure diff cross-compilers don't collide #414075
+	mv "${ED}"/usr/share/doc/{${PF},${CTARGET}-${PF}} || die
+}
diff --git a/dev-embedded/avr-libc/metadata.xml b/dev-embedded/avr-libc/metadata.xml
new file mode 100644
index 000000000000..2f1e470713ee
--- /dev/null
+++ b/dev-embedded/avr-libc/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>embedded@gentoo.org</email>
+		<name>Embedded Gentoo</name>
+	</maintainer>
+	<longdescription>
+		This package is part of the avr- binutils, -gcc, -lib toolchain for the Atmel microcontrollers.
+		These ebuilds have been created and submitted by Scott L. Price (dflytech.com).
+	</longdescription>
+</pkgmetadata>
-- 
cgit v1.2.3