From 6b933047f46efec1aa747570f945344254227457 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 15 Dec 2017 17:25:28 +0000
Subject: gentoo resync : 15.12.2017

---
 dev-db/sqlitebrowser/sqlitebrowser-3.10.1.ebuild | 69 ++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 dev-db/sqlitebrowser/sqlitebrowser-3.10.1.ebuild

(limited to 'dev-db/sqlitebrowser/sqlitebrowser-3.10.1.ebuild')

diff --git a/dev-db/sqlitebrowser/sqlitebrowser-3.10.1.ebuild b/dev-db/sqlitebrowser/sqlitebrowser-3.10.1.ebuild
new file mode 100644
index 000000000000..c661e29a9f2c
--- /dev/null
+++ b/dev-db/sqlitebrowser/sqlitebrowser-3.10.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils gnome2-utils xdg-utils
+
+DESCRIPTION="SQLite Database Browser"
+HOMEPAGE="http://sqlitebrowser.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-cpp/antlr-cpp:2
+	dev-db/sqlite:3
+	>=dev-libs/qcustomplot-2.0.0[qt5(+)]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	>=x11-libs/qscintilla-2.10.1:=[qt5(+)]
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	test? ( dev-qt/qttest:5 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.10.1-unbundle.patch
+)
+
+src_prepare() {
+	cmake-utils_src_prepare
+	# https://github.com/qingfengxia/qhexedit still bundled
+	# x11-libs/qscintilla[qt4?,qt5?] still bundled
+	find libs/{antlr-2.7.7,qcustomplot-source} -delete || die
+
+	sed -e "/^project/ s/\".*\"/sqlitebrowser/" -i CMakeLists.txt || die
+
+	if ! use test; then
+		sed -e "/qt5_use_modules/ s/ Test//" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_TESTING=$(usex test)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	doicon images/sqlitebrowser.svg
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3