From 6bc2e4d7c5906e46a8f275a876ead6ec41aca5bb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 10 Feb 2019 15:40:27 +0000
Subject: gentoo resync : 10.02.2019

---
 dev-db/opendbx/opendbx-1.4.6-r2.ebuild | 62 ++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-db/opendbx/opendbx-1.4.6-r2.ebuild

(limited to 'dev-db/opendbx/opendbx-1.4.6-r2.ebuild')

diff --git a/dev-db/opendbx/opendbx-1.4.6-r2.ebuild b/dev-db/opendbx/opendbx-1.4.6-r2.ebuild
new file mode 100644
index 000000000000..f3c0607e740f
--- /dev/null
+++ b/dev-db/opendbx/opendbx-1.4.6-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit flag-o-matic
+
+DESCRIPTION="OpenDBX - A database abstraction layer"
+HOMEPAGE="https://www.linuxnetworks.de/doc/index.php/OpenDBX"
+SRC_URI="https://www.linuxnetworks.de/opendbx/download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="firebird +mysql oracle postgres sqlite"
+RESTRICT="firebird? ( bindist )"
+
+RDEPEND="mysql? ( dev-db/mysql-connector-c:0= )
+	postgres? ( dev-db/postgresql:* )
+	sqlite? ( dev-db/sqlite:3 )
+	oracle? ( dev-db/oracle-instantclient-basic )
+	firebird? ( dev-db/firebird )"
+DEPEND="${RDEPEND} app-doc/doxygen app-text/docbook2X"
+
+REQUIRED_USE="|| ( firebird mysql oracle postgres sqlite )"
+
+PATCHES=( "${FILESDIR}/${PN}-doxy.patch" )
+
+pkg_setup() {
+	if use oracle && [[ ! -d ${ORACLE_HOME} ]]
+	then
+		die "Oracle support requested, but ORACLE_HOME not set to a valid directory!"
+	fi
+}
+
+src_configure() {
+	local backends=""
+
+	use firebird && backends="${backends} firebird"
+	use mysql && backends="${backends} mysql"
+	use oracle && backends="${backends} oracle"
+	use postgres && backends="${backends} pgsql"
+	use sqlite && backends="${backends} sqlite3"
+
+	use mysql && append-cppflags -I/usr/include/mysql
+	use firebird && append-cppflags -I/opt/firebird/include
+	use oracle && append-ldflags -L"${ORACLE_HOME}"/lib
+
+	econf --with-backends="${backends}"
+}
+
+src_compile() {
+	# bug #322221
+	emake -j1
+}
+
+src_install() {
+	emake -j1 install DESTDIR="${D}"
+	dodoc AUTHORS ChangeLog README
+
+	rm -f "${D}"/usr/$(get_libdir)/opendbx/*.{a,la}
+}
-- 
cgit v1.2.3