From 0f558761aa2dee1017b4751e4017205e015a9560 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Wed, 29 Jun 2022 12:04:12 +0100
Subject: gentoo resync : 29.12.2022

---
 dev-db/mydumper/mydumper-0.12.1.ebuild | 49 ++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 dev-db/mydumper/mydumper-0.12.1.ebuild

(limited to 'dev-db/mydumper/mydumper-0.12.1.ebuild')

diff --git a/dev-db/mydumper/mydumper-0.12.1.ebuild b/dev-db/mydumper/mydumper-0.12.1.ebuild
new file mode 100644
index 000000000000..e4e2ef8601ec
--- /dev/null
+++ b/dev-db/mydumper/mydumper-0.12.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_PV="$(ver_rs 3 -)"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="A high-performance multi-threaded backup (and restore) toolset for MySQL"
+HOMEPAGE="https://github.com/maxbube/mydumper"
+SRC_URI="https://github.com/maxbube/mydumper/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="app-arch/zstd
+	dev-db/mysql-connector-c:=
+	dev-libs/glib:2
+	dev-libs/libpcre
+	dev-libs/openssl:=
+	sys-libs/zlib:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	doc? ( dev-python/sphinx )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.10.5-atomic.patch" #654314
+)
+
+src_prepare() {
+	# respect user cflags; do not expand ${CMAKE_C_FLAGS} (!)
+	sed -i -e 's|-O3 -g -Werror|${CMAKE_C_FLAGS}|' CMakeLists.txt || die
+
+	# fix doc install path
+	sed -i -e "s|share/doc/mydumper|share/doc/${PF}|" docs/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(-DBUILD_DOCS=$(usex doc))
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3