From 068424b26532f3551a81421a9be67ed206e5c11a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 11 Aug 2021 07:02:28 +0100
Subject: gentoo resync : 11.08.2021

---
 dev-db/mydumper/mydumper-0.10.7.2.ebuild | 49 ++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 dev-db/mydumper/mydumper-0.10.7.2.ebuild

(limited to 'dev-db/mydumper/mydumper-0.10.7.2.ebuild')

diff --git a/dev-db/mydumper/mydumper-0.10.7.2.ebuild b/dev-db/mydumper/mydumper-0.10.7.2.ebuild
new file mode 100644
index 000000000000..6dcf0e83ab77
--- /dev/null
+++ b/dev-db/mydumper/mydumper-0.10.7.2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+MY_PV="$(ver_rs 3 -)"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="A high-performance multi-threaded backup (and restore) toolset for MySQL"
+HOMEPAGE="https://github.com/maxbube/mydumper"
+SRC_URI="https://github.com/maxbube/mydumper/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+RDEPEND="app-arch/zstd:=
+	dev-db/mysql-connector-c:=
+	dev-libs/glib:2
+	dev-libs/libpcre
+	dev-libs/openssl:=
+	sys-libs/zlib:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	doc? ( dev-python/sphinx )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.10.5-atomic.patch" #654314
+)
+
+src_prepare() {
+	# respect user cflags; do not expand ${CMAKE_C_FLAGS} (!)
+	sed -i -e 's|-Werror -O3 -g|${CMAKE_C_FLAGS}|' CMakeLists.txt || die
+
+	# fix doc install path
+	sed -i -e "s|share/doc/mydumper|share/doc/${PF}|" docs/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(-DBUILD_DOCS=$(usex doc))
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3