From 7c59acba5699c9c58090a7a738669669a7307023 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 21 Aug 2021 23:14:26 +0100
Subject: gentoo resync : 21.08.2021

---
 dev-db/mongodb/mongodb-4.2.12.ebuild | 174 -----------------------------------
 1 file changed, 174 deletions(-)
 delete mode 100644 dev-db/mongodb/mongodb-4.2.12.ebuild

(limited to 'dev-db/mongodb/mongodb-4.2.12.ebuild')

diff --git a/dev-db/mongodb/mongodb-4.2.12.ebuild b/dev-db/mongodb/mongodb-4.2.12.ebuild
deleted file mode 100644
index 11df6a441e4a..000000000000
--- a/dev-db/mongodb/mongodb-4.2.12.ebuild
+++ /dev/null
@@ -1,174 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7..9} )
-
-SCONS_MIN_VERSION="2.5.0"
-CHECKREQS_DISK_BUILD="2400M"
-CHECKREQS_DISK_USR="512M"
-CHECKREQS_MEMORY="1024M"
-
-inherit check-reqs flag-o-matic multiprocessing pax-utils python-any-r1 scons-utils systemd toolchain-funcs
-
-MY_P=${PN}-src-r${PV/_rc/-rc}
-
-DESCRIPTION="A high-performance, open source, schema-free document-oriented database"
-HOMEPAGE="https://www.mongodb.com"
-SRC_URI="https://fastdl.mongodb.org/src/${MY_P}.tar.gz"
-
-LICENSE="Apache-2.0 SSPL-1"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64"
-IUSE="debug kerberos lto ssl test +tools"
-RESTRICT="!test? ( test )"
-
-RDEPEND="acct-group/mongodb
-	acct-user/mongodb
-	>=app-arch/snappy-1.1.3
-	>=dev-cpp/yaml-cpp-0.6.2:=
-	>=dev-libs/boost-1.70:=[threads(+)]
-	>=dev-libs/libpcre-8.42[cxx]
-	app-arch/zstd
-	dev-libs/snowball-stemmer
-	net-libs/libpcap
-	>=sys-libs/zlib-1.2.11:=
-	kerberos? ( dev-libs/cyrus-sasl[kerberos] )
-	ssl? (
-		>=dev-libs/openssl-1.0.1g:0=
-	)"
-DEPEND="${RDEPEND}
-	${PYTHON_DEPS}
-	$(python_gen_any_dep '
-		test? ( dev-python/pymongo[${PYTHON_USEDEP}] dev-python/requests[${PYTHON_USEDEP}] )
-		>=dev-util/scons-2.5.0[${PYTHON_USEDEP}]
-		dev-python/cheetah3[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-		dev-python/pyyaml[${PYTHON_USEDEP}]
-	')
-	sys-libs/ncurses:0=
-	sys-libs/readline:0=
-	debug? ( dev-util/valgrind )"
-PDEPEND="tools? ( >=app-admin/mongo-tools-${PV} )"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-4.2.0-fix-scons.patch"
-	"${FILESDIR}/${PN}-4.2.10-no-compass.patch"
-)
-
-S="${WORKDIR}/${MY_P}"
-
-python_check_deps() {
-	if use test; then
-		has_version "dev-python/pymongo[${PYTHON_USEDEP}]" || return 1
-		has_version "dev-python/requests[${PYTHON_USEDEP}]" || return 1
-	fi
-
-	has_version ">=dev-util/scons-2.5.0[${PYTHON_USEDEP}]" &&
-	has_version "dev-python/cheetah3[${PYTHON_USEDEP}]" &&
-	has_version "dev-python/psutil[${PYTHON_USEDEP}]" &&
-	has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
-}
-
-pkg_pretend() {
-	if [[ -n ${REPLACING_VERSIONS} ]]; then
-		if ver_test "$REPLACING_VERSIONS" -lt 4.0; then
-			ewarn "To upgrade from a version earlier than the 4.0-series, you must"
-			ewarn "successively upgrade major releases until you have upgraded"
-			ewarn "to 4.0-series. Then upgrade to 4.2 series."
-		else
-			ewarn "Be sure to set featureCompatibilityVersion to 4.0 before upgrading."
-		fi
-	fi
-}
-
-src_prepare() {
-	default
-
-	# remove bundled libs
-	rm -r src/third_party/{boost-*,pcre-*,scons-*,snappy-*,yaml-cpp-*,zlib-*,zstandard-*} || die
-
-	# remove compass
-	rm -r src/mongo/installer/compass || die
-}
-
-src_configure() {
-	# https://github.com/mongodb/mongo/wiki/Build-Mongodb-From-Source
-	# --use-system-icu fails tests
-	# --use-system-tcmalloc is strongly NOT recommended:
-	scons_opts=(
-		CC="$(tc-getCC)"
-		CXX="$(tc-getCXX)"
-
-		--disable-warnings-as-errors
-		--use-system-boost
-		--use-system-pcre
-		--use-system-snappy
-		--use-system-stemmer
-		--use-system-yaml
-		--use-system-zlib
-		--use-system-zstd
-	)
-
-	use arm64 && scons_opts+=( --use-hardware-crc32=off ) # Bug 701300
-	use debug && scons_opts+=( --dbg=on )
-	use kerberos && scons_opts+=( --use-sasl-client )
-	use lto && scons_opts+=( --lto=on )
-	use ssl && scons_opts+=( --ssl )
-
-	# respect mongoDB upstream's basic recommendations
-	# see bug #536688 and #526114
-	if ! use debug; then
-		filter-flags '-m*'
-		filter-flags '-O?'
-	fi
-
-	default
-}
-
-src_compile() {
-	escons "${scons_opts[@]}" core tools
-}
-
-# FEATURES="test -usersandbox" emerge dev-db/mongodb
-src_test() {
-	ewarn "Tests may hang with FEATURES=usersandbox"
-	"${EPYTHON}" ./buildscripts/resmoke.py run --dbpathPrefix=test --suites core --jobs=$(makeopts_jobs) || die "Tests failed with ${EPYTHON}"
-}
-
-src_install() {
-	escons "${scons_opts[@]}" --nostrip install --prefix="${ED}"/usr
-
-	doman debian/mongo*.1
-	dodoc README docs/building.md
-
-	newinitd "${FILESDIR}/${PN}.initd-r3" ${PN}
-	newconfd "${FILESDIR}/${PN}.confd-r3" ${PN}
-	newinitd "${FILESDIR}/mongos.initd-r3" mongos
-	newconfd "${FILESDIR}/mongos.confd-r3" mongos
-
-	insinto /etc
-	newins "${FILESDIR}/${PN}.conf-r3" ${PN}.conf
-	newins "${FILESDIR}/mongos.conf-r2" mongos.conf
-
-	systemd_dounit "${FILESDIR}/${PN}.service"
-
-	insinto /etc/logrotate.d/
-	newins "${FILESDIR}/${PN}.logrotate" ${PN}
-
-	# see bug #526114
-	pax-mark emr "${ED}"/usr/bin/{mongo,mongod,mongos}
-
-	local x
-	for x in /var/{lib,log}/${PN}; do
-		diropts -m0750 -o mongodb -g mongodb
-		keepdir "${x}"
-	done
-}
-
-pkg_postinst() {
-	ewarn "Make sure to read the release notes and follow the upgrade process:"
-	ewarn "  https://docs.mongodb.com/manual/release-notes/$(ver_cut 1-2)/"
-	ewarn "  https://docs.mongodb.com/manual/release-notes/$(ver_cut 1-2)/#upgrade-procedures"
-}
-- 
cgit v1.2.3