From 2fd57282f0262ca084e05b0f2c63fbada395d02b Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 16 Jan 2022 20:27:28 +0000
Subject: gentoo resync : 16.01.2021

---
 dev-cpp/nlohmann_json/nlohmann_json-3.10.5.ebuild | 59 +++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-cpp/nlohmann_json/nlohmann_json-3.10.5.ebuild

(limited to 'dev-cpp/nlohmann_json/nlohmann_json-3.10.5.ebuild')

diff --git a/dev-cpp/nlohmann_json/nlohmann_json-3.10.5.ebuild b/dev-cpp/nlohmann_json/nlohmann_json-3.10.5.ebuild
new file mode 100644
index 000000000000..8bc260638ed9
--- /dev/null
+++ b/dev-cpp/nlohmann_json/nlohmann_json-3.10.5.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+#DOCS_BUILDER="mkdocs"
+# Needs unpackaged plantuml-markdown too
+# ... but plantuml (Python bindings anyway) need network access to generate bits at runtime.
+#DOCS_DEPEND="dev-python/mkdocs-material-extensions dev-python/mkdocs-minify-plugin"
+#DOCS_DIR="doc/mkdocs"
+inherit cmake
+
+# Check https://github.com/nlohmann/json/blob/develop/cmake/download_test_data.cmake to find test archive version
+TEST_VERSION="3.0.0"
+DESCRIPTION="JSON for Modern C++"
+HOMEPAGE="https://github.com/nlohmann/json https://nlohmann.github.io/json/"
+SRC_URI="
+	https://github.com/nlohmann/json/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	test? ( https://github.com/nlohmann/json_test_data/archive/v${TEST_VERSION}.tar.gz -> ${PN}-testdata-${TEST_VERSION}.tar.gz )"
+S="${WORKDIR}/json-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+# Need to report failing tests upstream
+# Tests only just added, large test suite, majority pass
+RESTRICT="test"
+
+DOCS=( ChangeLog.md README.md )
+
+src_configure() {
+	# Tests are built by default so we can't group the test logic below
+	local mycmakeargs=(
+		-DJSON_MultipleHeaders=ON
+		-DJSON_BuildTests=$(usex test)
+	)
+
+	# Define test data directory here to avoid unused var QA warning, bug #747826
+	use test && mycmakeargs+=( -DJSON_TestDataDirectory="${S}"/json_test_data )
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cd "${BUILD_DIR}/test" || die
+
+	# Skip certain tests needing git per upstream
+	# https://github.com/nlohmann/json/issues/2189
+	local myctestargs=(
+		"-LE git_required"
+	)
+
+	cmake_src_test
+}
-- 
cgit v1.2.3