From d682a95de35077b0728025627e082b67339fa249 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 1 Jan 2023 02:21:02 +0000
Subject: gentoo auto-resync : 01:01:2023 - 02:21:02

---
 dev-cpp/libxmlpp/libxmlpp-5.0.2.ebuild | 57 ++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 dev-cpp/libxmlpp/libxmlpp-5.0.2.ebuild

(limited to 'dev-cpp/libxmlpp/libxmlpp-5.0.2.ebuild')

diff --git a/dev-cpp/libxmlpp/libxmlpp-5.0.2.ebuild b/dev-cpp/libxmlpp/libxmlpp-5.0.2.ebuild
new file mode 100644
index 000000000000..7a9d793a15d0
--- /dev/null
+++ b/dev-cpp/libxmlpp/libxmlpp-5.0.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+GNOME_ORG_MODULE="${PN/pp/++}"
+
+inherit gnome2 meson
+
+DESCRIPTION="C++ wrapper for the libxml2 XML parser library"
+HOMEPAGE="http://libxmlplusplus.sourceforge.net/"
+
+LICENSE="LGPL-2.1"
+SLOT="5.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/libxml2-2.7.7
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		dev-cpp/mm-common
+		app-doc/doxygen
+		media-gfx/graphviz
+		dev-libs/libxslt
+	)
+"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/install_docdir = /s/'doc'/'gtk-doc'/" \
+		docs/reference/meson.build || die
+	sed -i \
+		-e "/install_tutorialdir = /s/'doc'/'gtk-doc'/" \
+		docs/manual/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dmaintainer-mode=false
+		-Dwarnings=min
+		-Ddist-warnings=max
+		-Dbuild-deprecated-api=true
+		$(meson_use doc build-documentation)
+		-Dvalidation=false
+		-Dbuild-pdf=false
+		-Dbuild-examples=false
+		$(meson_use test build-tests)
+		-Dmsvc14x-parallel-installable=false
+	)
+	meson_src_configure
+}
-- 
cgit v1.2.3