From 8376ef56580626e9c0f796d5b85b53a0a1c7d5f5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 14 Jul 2018 21:03:06 +0100
Subject: gentoo resync : 14.07.2018

---
 dev-cpp/gtest/gtest-1.7.0-r1.ebuild | 50 +++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 dev-cpp/gtest/gtest-1.7.0-r1.ebuild

(limited to 'dev-cpp/gtest/gtest-1.7.0-r1.ebuild')

diff --git a/dev-cpp/gtest/gtest-1.7.0-r1.ebuild b/dev-cpp/gtest/gtest-1.7.0-r1.ebuild
new file mode 100644
index 000000000000..f1185b2db0cc
--- /dev/null
+++ b/dev-cpp/gtest/gtest-1.7.0-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+AUTOTOOLS_AUTORECONF=1
+AUTOTOOLS_IN_SOURCE_BUILD=1
+# Python is required for tests and some build tasks.
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils python-any-r1 autotools-multilib
+
+DESCRIPTION="Google C++ Testing Framework"
+HOMEPAGE="https://github.com/google/googletest"
+SRC_URI="https://github.com/google/googletest/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="examples static-libs"
+
+DEPEND="${PYTHON_DEPS}"
+RDEPEND=""
+
+PATCHES=(
+	"${FILESDIR}/configure-fix-pthread-linking.patch" #371647
+)
+
+src_prepare() {
+	sed -i -e "s|/tmp|${T}|g" test/gtest-filepath_test.cc || die
+	sed -i -r \
+		-e '/^install-(data|exec)-local:/s|^.*$|&\ndisabled-&|' \
+		Makefile.am || die
+	autotools-multilib_src_prepare
+}
+
+multilib_src_install() {
+	default
+	multilib_is_native_abi && dobin scripts/gtest-config
+}
+
+multilib_src_install_all() {
+	prune_libtool_files --all
+	einstalldocs
+
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/examples
+		doins samples/*.{cc,h}
+	fi
+}
-- 
cgit v1.2.3