From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 dev-cpp/gmock/gmock-1.7.0-r1.ebuild | 61 +++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 dev-cpp/gmock/gmock-1.7.0-r1.ebuild

(limited to 'dev-cpp/gmock/gmock-1.7.0-r1.ebuild')

diff --git a/dev-cpp/gmock/gmock-1.7.0-r1.ebuild b/dev-cpp/gmock/gmock-1.7.0-r1.ebuild
new file mode 100644
index 000000000000..42e424f63b84
--- /dev/null
+++ b/dev-cpp/gmock/gmock-1.7.0-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="4"
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit epatch libtool multilib-minimal python-any-r1
+
+DESCRIPTION="Google's C++ mocking framework"
+HOMEPAGE="https://github.com/google/googlemock"
+SRC_URI="https://googlemock.googlecode.com/files/${P}.zip"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86"
+IUSE="static-libs test"
+
+RDEPEND="=dev-cpp/gtest-${PV}*[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? ( ${PYTHON_DEPS} )
+	app-arch/unzip"
+
+pkg_setup() {
+	# Stub to disable python_setup running when USE=-test.
+	# We'll handle it down in src_test ourselves.
+	:
+}
+
+src_unpack() {
+	default
+	# make sure we always use the system one
+	rm -r "${S}"/gtest/{Makefile,configure}* || die
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-gcc6.patch
+
+	sed -i -r \
+		-e '/^install-(data|exec)-local:/s|^.*$|&\ndisabled-&|' \
+		Makefile.in
+	elibtoolize
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} econf $(use_enable static-libs static)
+}
+
+multilib_src_test() {
+	python_setup
+	emake check
+}
+
+multilib_src_install() {
+	default
+	dobin scripts/gmock-config
+}
+
+multilib_src_install_all() {
+	use static-libs || find "${ED}" -name '*.la' -delete
+}
-- 
cgit v1.2.3