From 36ac65103bf5503e5bad1ecc7e8cb9e7643f6840 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 13 Sep 2019 17:49:31 +0100
Subject: Revert "gentoo resync : 13.09.2019"

This reverts commit a1392efe64137262023d92492396ca9156d22396.
---
 .../gentoo-syntax/gentoo-syntax-20181023.ebuild    | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 app-vim/gentoo-syntax/gentoo-syntax-20181023.ebuild

(limited to 'app-vim/gentoo-syntax/gentoo-syntax-20181023.ebuild')

diff --git a/app-vim/gentoo-syntax/gentoo-syntax-20181023.ebuild b/app-vim/gentoo-syntax/gentoo-syntax-20181023.ebuild
new file mode 100644
index 000000000000..f1853ed776bb
--- /dev/null
+++ b/app-vim/gentoo-syntax/gentoo-syntax-20181023.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit vim-plugin
+
+DESCRIPTION="vim plugin: Gentoo and Portage syntax highlighting"
+HOMEPAGE="https://github.com/gentoo/gentoo-syntax"
+SRC_URI="https://gitweb.gentoo.org/proj/gentoo-syntax.git/snapshot/${P}.tar.bz2"
+
+LICENSE="vim"
+SLOT="0"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 ~riscv s390 sh sparc x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="ignore-glep31"
+
+VIM_PLUGIN_HELPFILES="gentoo-syntax"
+VIM_PLUGIN_MESSAGES="filetype"
+
+src_prepare() {
+	default
+	if use ignore-glep31 ; then
+		for f in ftplugin/*.vim ; do
+			ebegin "Removing UTF-8 rules from ${f} ..."
+			sed -i -e 's~\(setlocal fileencoding=utf-8\)~" \1~' ${f} \
+				|| die "waah! bad sed voodoo. need more goats."
+			eend $?
+		done
+	fi
+}
+
+pkg_postinst() {
+	vim-plugin_pkg_postinst
+
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		if use ignore-glep31 1>/dev/null ; then
+			ewarn "You have chosen to disable the rules which ensure GLEP 31"
+			ewarn "compliance. When editing ebuilds, please make sure you get"
+			ewarn "the character set correct."
+		fi
+	fi
+}
-- 
cgit v1.2.3