From 95461df035e3867364495f065e5e805bf629b2d7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 26 Oct 2021 00:10:07 +0100
Subject: gentoo resync : 25.10.2021

---
 app-text/sigil/sigil-1.8.0.ebuild | 72 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 app-text/sigil/sigil-1.8.0.ebuild

(limited to 'app-text/sigil/sigil-1.8.0.ebuild')

diff --git a/app-text/sigil/sigil-1.8.0.ebuild b/app-text/sigil/sigil-1.8.0.ebuild
new file mode 100644
index 000000000000..11d9e2e1dd89
--- /dev/null
+++ b/app-text/sigil/sigil-1.8.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="tk"
+
+inherit xdg cmake python-single-r1
+
+DESCRIPTION="Multi-platform WYSIWYG ebook editor for ePub format"
+HOMEPAGE="https://sigil-ebook.com/ https://github.com/Sigil-Ebook/Sigil"
+SRC_URI="https://github.com/Sigil-Ebook/Sigil/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P^}"
+
+LICENSE="GPL-3+ Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+plugins system-mathjax"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-text/hunspell:=
+	dev-libs/libpcre:3=[pcre16]
+	$(python_gen_cond_dep '
+		dev-python/css-parser[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]')
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	sys-libs/zlib[minizip]
+	plugins? ( $(python_gen_cond_dep '
+		dev-python/chardet[${PYTHON_USEDEP}]
+		dev-python/cssselect[${PYTHON_USEDEP}]
+		dev-python/dulwich[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/regex[${PYTHON_USEDEP}]') )
+	system-mathjax? ( dev-libs/mathjax )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( ChangeLog.txt README.md )
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_BUNDLED_DICTS=0
+		-DUSE_SYSTEM_LIBS=1
+		-DSYSTEM_LIBS_REQUIRED=1
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DPYTHON_LIBRARY="$(python_get_library_path)"
+		-DPYTHON_INCLUDE_DIR="$(python_get_includedir)"
+	)
+	use system-mathjax && mycmakeargs+=( -DMATHJAX_DIR="${EPREFIX}"/usr/share/mathjax )
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	python_fix_shebang "${ED}"/usr/share/sigil/
+	python_optimize "${ED}"/usr/share/sigil/
+}
-- 
cgit v1.2.3