From d18bf1e01b65ee4bf0c804e2843b282d3d4e5d7c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 15 Jun 2021 14:57:03 +0100
Subject: gentoo resync : 15.06.2021

---
 app-text/recode/recode-3.7.9.ebuild | 58 +++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 app-text/recode/recode-3.7.9.ebuild

(limited to 'app-text/recode/recode-3.7.9.ebuild')

diff --git a/app-text/recode/recode-3.7.9.ebuild b/app-text/recode/recode-3.7.9.ebuild
new file mode 100644
index 000000000000..163176ef093c
--- /dev/null
+++ b/app-text/recode/recode-3.7.9.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit flag-o-matic python-any-r1 toolchain-funcs
+
+DESCRIPTION="Convert files between various character sets"
+HOMEPAGE="https://github.com/rrthomas/recode"
+SRC_URI="https://github.com/rrthomas/recode/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+# librecode soname version
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x86-solaris"
+IUSE="nls test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="virtual/libiconv"
+DEPEND="
+	${RDEPEND}
+	sys-devel/flex
+"
+BDEPEND="
+	nls? ( sys-devel/gettext )
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	if use test ; then
+		has_version -b "dev-python/cython[${PYTHON_USEDEP}]" || return 1
+	fi
+}
+
+src_configure() {
+	tc-export CC LD
+
+	# on solaris -lintl is needed to compile
+	[[ ${CHOST} == *-solaris* ]] && append-libs "-lintl"
+
+	# --without-included-gettext means we always use system headers
+	# and library
+	econf \
+		$(use_enable nls) \
+		--disable-static
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3