From fab849d1daed0ba7f2ac497d07985c3dbb692543 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 16 Jun 2019 21:23:20 +0100
Subject: gentoo resync : 16.06.2019

---
 app-text/qpdf/qpdf-8.4.2.ebuild | 57 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 app-text/qpdf/qpdf-8.4.2.ebuild

(limited to 'app-text/qpdf/qpdf-8.4.2.ebuild')

diff --git a/app-text/qpdf/qpdf-8.4.2.ebuild b/app-text/qpdf/qpdf-8.4.2.ebuild
new file mode 100644
index 000000000000..320e39eb2a68
--- /dev/null
+++ b/app-text/qpdf/qpdf-8.4.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Command-line tool for structural, content-preserving transformation of PDF files"
+HOMEPAGE="http://qpdf.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qpdf/${P}.tar.gz"
+
+LICENSE="|| ( Apache-2.0 Artistic-2 )"
+
+# subslot = libqpdf soname version
+SLOT="0/21"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~m68k-mint ~sparc-solaris"
+IUSE="doc examples perl static-libs test"
+
+CDEPEND="
+	sys-libs/zlib
+	virtual/jpeg:0=
+"
+DEPEND="${CDEPEND}
+	test? (
+		sys-apps/diffutils
+		media-libs/tiff
+		app-text/ghostscript-gpl[tiff]
+	)
+"
+# Only need perl for the installed tools.
+RDEPEND="${CDEPEND}
+	perl? ( >=dev-lang/perl-5.8 )
+"
+
+DOCS=( ChangeLog README.md TODO )
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		$(use_enable test test-compare-images)
+	)
+	CONFIG_SHELL=/bin/bash econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if ! use perl ; then
+		rm "${ED}"/usr/bin/fix-qdf || die
+		rm "${ED}"/usr/share/man/man1/fix-qdf.1 || die
+	fi
+
+	if use examples ; then
+		dobin examples/build/.libs/*
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3