From 4cbcc855382a06088e2f016f62cafdbcb7e40665 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 20 Mar 2022 00:40:44 +0000
Subject: gentoo resync : 20.03.2022

---
 app-text/podofo/Manifest            |   2 +
 app-text/podofo/podofo-0.9.7.ebuild | 114 ++++++++++++++++++++++++++++++++++++
 2 files changed, 116 insertions(+)
 create mode 100644 app-text/podofo/podofo-0.9.7.ebuild

(limited to 'app-text/podofo')

diff --git a/app-text/podofo/Manifest b/app-text/podofo/Manifest
index 4143e9ce4f59..4a93511411c7 100644
--- a/app-text/podofo/Manifest
+++ b/app-text/podofo/Manifest
@@ -1,4 +1,6 @@
 AUX podofo-0.9.6_p20190928-cmake_lua_version.patch 522 BLAKE2B b911b2ab2b35f5eccb58b32e575a775fe43cac1576831bb4e47d10c666a1e7040d8c01c865ee63ef1c3ff3c1a1feb2059dc25c71924b61995302dad21c32c868 SHA512 953f41b44468918aa96af42ecf3de8e3dd0d7721ed7c6283d8a6d44941caf70d9ef63d7d59ee1d94081fdc91a915ba8770bc335f8af5d60b24cd1f6c04698f6f
 DIST podofo-0.9.6_p20190928.tar.xz 747532 BLAKE2B 39d051e6adca85bf0f124e5d48e1ff88dc951d7c1b38bc76dc7e3640ea9c3f8a59c6ba9a9105a263234e94932e450bec12dde455850dbf96cd7eec3e69a1a28d SHA512 b9d46fb02eeba61190a0efd17b507bba62d7246af6fff3c3514c9970e99e085f9aad92baa05cc6cf0a8c3c2843554099c904bff10be54dbb4d4cb7de460fc3cc
+DIST podofo-0.9.7.tar.gz 1005247 BLAKE2B d8f123008d272c1c39f60438d7cd6112cdd851488775e7e0fcb3fd9c4669fd64867fa293ef18b3189eac01f84a8a6b3c536171528f2b6097a5fe181c98501a71 SHA512 0e699739c2fb7d4d02ffca371504bb19f3a8a97ddcbfc06f8d9636db9e73064b4f633f7f09bce92140bb2174610ad68c1e5f8460d474d176ab803ed28295251b
 EBUILD podofo-0.9.6_p20190928-r100.ebuild 4628 BLAKE2B c56190961516725347024e985203929e09dd46addd0f3fb74ca42402231388e053a3d0b723aed6b3805e11586f03c05a7462931890d6eaf889c9f3c2c0ea5779 SHA512 f7568d43e7afcfe1e59f34ff91a342995cccdeec13073b09b326d2e1b2f9d14ff91c08e64e9fa37f9bcca69d205d2afccd428dd3915da4022bd1f57047474741
+EBUILD podofo-0.9.7.ebuild 3068 BLAKE2B 2e840d40db7a62fba8106e85f569f4ae033353fb0110f94fb9821eb65b23b116e1e2fba23dbeceb5140547a8b99a81da216dca09e02996940767a3498742cca8 SHA512 a2cec4effac6c690868d33e51b589bb284adfb0cae20630dda1b559b3ae4974144d388959c5d6978b23fb03249a99ca1368af0fe065f8ac59cbc881b1c4d2586
 MISC metadata.xml 510 BLAKE2B a8b777ebbbbadbb251c30aa0c662509559849d74c326e38d8ef965aa32f4cdd613a8d2251771d43fd217dbedd195dc11c8167e09bb2aa7ecf064a7dc2e13abe9 SHA512 d47dfa7ef44f0f0758662550afafd90e2566ad1ee418173aa27ead580ec0d328e0facd812e68b9701a2a6d7e6dcb9d62576c62c9a441c2c7f2fd664cd8f92bbc
diff --git a/app-text/podofo/podofo-0.9.7.ebuild b/app-text/podofo/podofo-0.9.7.ebuild
new file mode 100644
index 000000000000..5510e90dad7e
--- /dev/null
+++ b/app-text/podofo/podofo-0.9.7.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} )
+
+inherit cmake flag-o-matic lua-single toolchain-funcs
+
+DESCRIPTION="PoDoFo is a C++ library to work with the PDF file format"
+HOMEPAGE="https://sourceforge.net/projects/podofo/"
+SRC_URI="https://cfhcable.dl.sourceforge.net/project/podofo/podofo/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="+boost idn debug test +tools"
+RESTRICT="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}
+	test? ( tools )"
+
+RDEPEND="${LUA_DEPS}
+	idn? ( net-dns/libidn:= )
+	dev-libs/openssl:0=
+	media-libs/fontconfig:=
+	media-libs/freetype:2=
+	virtual/jpeg:0=
+	media-libs/libpng:0=
+	media-libs/tiff:0=
+	sys-libs/zlib:="
+DEPEND="${RDEPEND}
+	test? ( dev-util/cppunit )
+"
+
+BDEPEND="virtual/pkgconfig
+	boost? ( dev-util/boost-build )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9.6_p20190928-cmake_lua_version.patch
+)
+
+DOCS="AUTHORS ChangeLog TODO"
+
+src_prepare() {
+	cmake_src_prepare
+	local x sed_args
+
+	# bug 620934 - Disable linking with cppunit when possible, since it
+	# triggers errors with some older compilers.
+	use test || sed -e 's:^FIND_PACKAGE(CppUnit):#\0:' -i CMakeLists.txt || die
+
+	# bug 556962
+	sed -i -e 's|Decrypt( pEncryptedBuffer, nOutputLen, pDecryptedBuffer, m_lLen );|Decrypt( pEncryptedBuffer, (pdf_long)nOutputLen, pDecryptedBuffer, (pdf_long\&)m_lLen );|' \
+		test/unit/EncryptTest.cpp || die
+
+	sed -i \
+		-e "s:LIBDIRNAME \"lib\":LIBDIRNAME \"$(get_libdir)\":" \
+		-e "s:LIBIDN_FOUND:HAVE_LIBIDN:g" \
+		CMakeLists.txt || die
+
+	# Use pkg-config to find headers for bug #459404.
+	sed_args=
+	for x in $($(tc-getPKG_CONFIG) --cflags freetype2) ; do
+		[[ ${x} == -I* ]] || continue
+		x=${x#-I}
+		if [[ -f ${x}/ft2build.h ]] ; then
+			sed_args+=" -e s:/usr/include/\\r\$:${x}:"
+		elif [[ -f ${x}/freetype/config/ftheader.h ]] ; then
+			sed_args+=" -e s:/usr/include/freetype2\\r\$:${x}:"
+		fi
+	done
+	[[ -n ${sed_args} ]] && \
+		{ sed -i ${sed_args} cmake/modules/FindFREETYPE.cmake || die; }
+
+	# Bug #407015: fix to compile with Lua 5.2+
+	case "${ELUA}" in
+		lua5-1|luajit)
+			;;
+		*)
+			sed -e 's: lua_open(: luaL_newstate(:' \
+				-e 's: luaL_getn(: lua_rawlen(:' -i \
+				tools/podofocolor/luaconverter.cpp \
+				tools/podofoimpose/planreader_lua.cpp || die
+			;;
+	esac
+}
+
+src_configure() {
+
+	# Bug #381359: undefined reference to `PoDoFo::PdfVariant::DelayedLoadImpl()'
+	filter-flags -fvisibility-inlines-hidden
+
+	mycmakeargs+=(
+		"-DPODOFO_BUILD_SHARED=1"
+		"-DPODOFO_HAVE_JPEG_LIB=1"
+		"-DPODOFO_HAVE_PNG_LIB=1"
+		"-DPODOFO_HAVE_TIFF_LIB=1"
+		"-DWANT_FONTCONFIG=1"
+		"-DUSE_STLPORT=0"
+		-DLUA_VERSION="$(lua_get_version)"
+		-DWANT_BOOST=$(usex boost ON OFF)
+		-DHAVE_LIBIDN=$(usex idn ON OFF)
+		-DPODOFO_HAVE_CPPUNIT=$(usex test ON OFF)
+		-DPODOFO_BUILD_LIB_ONLY=$(usex tools OFF ON)
+		)
+
+	cmake_src_configure
+	mkdir -p "${S}/test/TokenizerTest/objects" || die
+}
+
+src_test() {
+	cd "${BUILD_DIR}"/test/unit || die
+	./podofo-test --selftest || die "self test failed"
+}
-- 
cgit v1.2.3