From 4cbcc855382a06088e2f016f62cafdbcb7e40665 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 20 Mar 2022 00:40:44 +0000
Subject: gentoo resync : 20.03.2022

---
 app-text/paperwork/paperwork-2.1.1.ebuild | 43 +++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 app-text/paperwork/paperwork-2.1.1.ebuild

(limited to 'app-text/paperwork/paperwork-2.1.1.ebuild')

diff --git a/app-text/paperwork/paperwork-2.1.1.ebuild b/app-text/paperwork/paperwork-2.1.1.ebuild
new file mode 100644
index 000000000000..27169a2d1a1f
--- /dev/null
+++ b/app-text/paperwork/paperwork-2.1.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 xdg
+
+DESCRIPTION="a personal document manager for scanned documents (and PDFs)"
+HOMEPAGE="https://gitlab.gnome.org/World/OpenPaperwork"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="~app-text/openpaperwork-core-${PV}[${PYTHON_USEDEP}]
+	~app-text/openpaperwork-gtk-${PV}[${PYTHON_USEDEP}]
+	~app-text/paperwork-backend-${PV}[${PYTHON_USEDEP}]
+	dev-python/libpillowfight[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pyenchant[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	>=dev-python/pyocr-0.3.0[${PYTHON_USEDEP}]
+	dev-python/pyxdg[${PYTHON_USEDEP}]
+	media-libs/libinsane
+	x11-libs/libnotify[introspection]"
+DEPEND="${RDEPEND}"
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# This queries tesseract languages and will fail sandbox with
+	# USE=opencl, bugs #793446 #830012
+	addpredict /dev/nvidiactl
+	addpredict /dev/kfd
+
+	PYTHONPATH="src" "${EPYTHON}" src/paperwork_gtk/main.py install \
+		--icon_base_dir="${ED}"/usr/share/icons \
+		--data_base_dir="${ED}"/usr/share
+}
-- 
cgit v1.2.3