From e0722f6145f1e8db6281ff135d83442091b31620 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 18 Jul 2023 13:00:52 +0100
Subject: gentoo auto-resync : 18:07:2023 - 13:00:52

---
 app-text/pandoc-bin/pandoc-bin-2.19.2.ebuild | 52 ++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 app-text/pandoc-bin/pandoc-bin-2.19.2.ebuild

(limited to 'app-text/pandoc-bin/pandoc-bin-2.19.2.ebuild')

diff --git a/app-text/pandoc-bin/pandoc-bin-2.19.2.ebuild b/app-text/pandoc-bin/pandoc-bin-2.19.2.ebuild
new file mode 100644
index 000000000000..61ad41c6b2b6
--- /dev/null
+++ b/app-text/pandoc-bin/pandoc-bin-2.19.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=${PN//-bin/}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Conversion between markup formats (binary package)"
+HOMEPAGE="https://pandoc.org/
+	https://github.com/jgm/pandoc/"
+
+BASE_URI="https://github.com/jgm/${MY_PN}/releases/download/${PV}/${MY_P}"
+SRC_URI="
+	amd64? ( ${BASE_URI}-linux-amd64.tar.gz )
+	arm64? ( ${BASE_URI}-linux-arm64.tar.gz )
+"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm64"
+IUSE="+pandoc-symlink"
+
+RDEPEND="pandoc-symlink? ( !${CATEGORY}/${MY_PN} )"
+
+QA_FLAGS_IGNORED="usr/bin/${PN}"
+QA_PRESTRIPPED="${QA_FLAGS_IGNORED}"
+
+src_unpack() {
+	default
+
+	# Manpages are gzipped.
+	unpack "${S}"/share/man/man1/*.1.gz
+}
+
+src_install() {
+	exeinto /usr/bin
+	newexe bin/${MY_PN} ${PN}
+	dosym ${PN} /usr/bin/pandoc-server-bin
+
+	newman "${WORKDIR}"/${MY_PN}-server.1 pandoc-server-bin.1
+	newman "${WORKDIR}"/${MY_PN}.1 ${PN}.1
+
+	if use pandoc-symlink ; then
+		dosym ${PN} /usr/bin/${MY_PN}
+		dosym pandoc-server-bin /usr/bin/${MY_PN}-server
+
+		dosym ${PN}.1 /usr/share/man/man1/${MY_PN}.1
+		dosym pandoc-server-bin.1 /usr/share/man/man1/${MY_PN}-server.1
+	fi
+}
-- 
cgit v1.2.3