From b7ebc951da8800f711142f69d9d958bde67a112d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 28 Apr 2019 09:54:45 +0100
Subject: gentoo resync : 28.04.2019

---
 app-text/libmwaw/Manifest              |  4 ++-
 app-text/libmwaw/libmwaw-0.3.15.ebuild | 52 ++++++++++++++++++++++++++++++++++
 app-text/libmwaw/libmwaw-9999.ebuild   | 41 ++++++++++++++-------------
 3 files changed, 77 insertions(+), 20 deletions(-)
 create mode 100644 app-text/libmwaw/libmwaw-0.3.15.ebuild

(limited to 'app-text/libmwaw')

diff --git a/app-text/libmwaw/Manifest b/app-text/libmwaw/Manifest
index cbf6be38a29a..a835bc33d7f6 100644
--- a/app-text/libmwaw/Manifest
+++ b/app-text/libmwaw/Manifest
@@ -1,4 +1,6 @@
 DIST libmwaw-0.3.14.tar.xz 1276240 BLAKE2B 34a5b118064dcac37834c83b2b5a61303f3e2eb70e41322845ff7661a5494c0b85db0bb07c6bf1f357c2027cab1c515eade58bb6b4fdf845a81d4d079a414b98 SHA512 6893a7a8a72765a66973a94bc7de8b3b6061aa85fd9cca5e73cb2a4024cbe81f0c030df0b6383f24835643259c361efda5527813bb84a1b08d0089d509215888
+DIST libmwaw-0.3.15.tar.xz 1289744 BLAKE2B 9aed923542e795904761e4969299785906aa65c735541788d91eb41e80420ac6c6df4df5e0cfa156c71d4e100c601e5e984de10c6a5f66eebe6ffb5f0374cc1d SHA512 0b2443fc6bc9da9247f7585743424df440f89317af989018d8b972864bf91e3c5cd78c39094a45d9de8114906b2b2a93f68ddb967af8565e4b499f643d86e682
 EBUILD libmwaw-0.3.14.ebuild 1015 BLAKE2B eb9a228a21d0bf53be7af47baf26458f1cea0c6a2e4f4bbff499533c9b7a9c226fe401bc112e4009972232ca2cf96846085cb2d9af0d37b62277b5c8e5478cf1 SHA512 58f7477e5af9f99a2248ec8f233cc5c1ec9d679c1f0a6dc4a278beb718140eb762c3c3a16cd43357c779b16b1341c2e843002a2559378022aabf7f92053caf75
-EBUILD libmwaw-9999.ebuild 1010 BLAKE2B caf4e52dadd33b6348da5ae194d1d9364fb972dfbd4ed05b97a639f835958857b023c3a0afa658288e616e7500d3ae62fa6ee7de213b656b3084cb96633dd4d7 SHA512 313ac932f39b04df8668fddc72004ab421bb6415ca90569cde318345c40512cea7fca01f546ff044e92d373b11f5441a90be178ca6e1bac12be6743a0e6faf46
+EBUILD libmwaw-0.3.15.ebuild 1027 BLAKE2B e51984196fe26cf9e7ba8ebe2e6de35c58443d3db82a65ee5d0358ac05f7905227670e05106e89d52ecb264f1e3833fe38917fce36a1fb6a2449228d90409d82 SHA512 9b530edcb03829b26715e09c5b99dc5f08bda876317813bf4589a7366a4bf20c5e2f0604792d103d6f50f2f7c4439a19dc60e362bef8627026508910eabf7837
+EBUILD libmwaw-9999.ebuild 1027 BLAKE2B e51984196fe26cf9e7ba8ebe2e6de35c58443d3db82a65ee5d0358ac05f7905227670e05106e89d52ecb264f1e3833fe38917fce36a1fb6a2449228d90409d82 SHA512 9b530edcb03829b26715e09c5b99dc5f08bda876317813bf4589a7366a4bf20c5e2f0604792d103d6f50f2f7c4439a19dc60e362bef8627026508910eabf7837
 MISC metadata.xml 403 BLAKE2B cbddacc98e4f22e521d739150ee4044b93c297dbd6d220a445192a3d1a6316491d6ed72ada8bd138c287133fcaf1b3d5ce580e68dd3ec071d36abbc1b05b4b6d SHA512 12cebd7bdaff6a793598f40cb11f4ae6681dcb29b18ecb7db92681abf1f6d4ce0281ae292c84106a143c0ff5ff3395e37604b3576c6a479001fc351dba10c7ed
diff --git a/app-text/libmwaw/libmwaw-0.3.15.ebuild b/app-text/libmwaw/libmwaw-0.3.15.ebuild
new file mode 100644
index 000000000000..cc207bd575ba
--- /dev/null
+++ b/app-text/libmwaw/libmwaw-0.3.15.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = 9999 ]]; then
+	EGIT_REPO_URI="https://git.code.sf.net/p/libmwaw/libmwaw"
+	inherit autotools git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Library parsing many pre-OSX MAC text formats"
+HOMEPAGE="https://sourceforge.net/p/libmwaw/wiki/Home/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc static-libs tools"
+
+BDEPEND="
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+DEPEND="
+	dev-libs/librevenge
+	sys-libs/zlib
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	# zip is hard enabled as the zlib is dep on the rdeps anyway
+	local myeconfargs=(
+		--enable-zip
+		--disable-werror
+		$(use_with doc docs)
+		$(use_enable static-libs static)
+		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/app-text/libmwaw/libmwaw-9999.ebuild b/app-text/libmwaw/libmwaw-9999.ebuild
index 7dde090fa754..cc207bd575ba 100644
--- a/app-text/libmwaw/libmwaw-9999.ebuild
+++ b/app-text/libmwaw/libmwaw-9999.ebuild
@@ -1,32 +1,33 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-EGIT_REPO_URI="git://git.code.sf.net/p/libmwaw/libmwaw"
-[[ ${PV} == 9999 ]] && inherit autotools git-r3
+if [[ ${PV} = 9999 ]]; then
+	EGIT_REPO_URI="https://git.code.sf.net/p/libmwaw/libmwaw"
+	inherit autotools git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
 
 DESCRIPTION="Library parsing many pre-OSX MAC text formats"
 HOMEPAGE="https://sourceforge.net/p/libmwaw/wiki/Home/"
-[[ ${PV} == 9999 ]] || SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-
-[[ ${PV} == 9999 ]] || \
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-
 IUSE="doc static-libs tools"
 
-RDEPEND="
-	dev-libs/librevenge
-	sys-libs/zlib
-"
-DEPEND="${RDEPEND}
+BDEPEND="
 	sys-devel/libtool
 	virtual/pkgconfig
 	doc? ( app-doc/doxygen )
 "
+DEPEND="
+	dev-libs/librevenge
+	sys-libs/zlib
+"
+RDEPEND="${DEPEND}"
 
 src_prepare() {
 	default
@@ -35,12 +36,14 @@ src_prepare() {
 
 src_configure() {
 	# zip is hard enabled as the zlib is dep on the rdeps anyway
-	econf \
-		--enable-zip \
-		--disable-werror \
-		$(use_with doc docs) \
-		$(use_enable static-libs static) \
+	local myeconfargs=(
+		--enable-zip
+		--disable-werror
+		$(use_with doc docs)
+		$(use_enable static-libs static)
 		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
 }
 
 src_install() {
-- 
cgit v1.2.3