From 276bf8cd1947ad9dd4295234e2ede5793ee301e6 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Mon, 11 Jul 2022 19:30:42 +0100
Subject: gentoo auto-resync : 11:07:2022 - 19:30:41

---
 app-text/liblangtag/liblangtag-0.6.4.ebuild | 55 +++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 app-text/liblangtag/liblangtag-0.6.4.ebuild

(limited to 'app-text/liblangtag/liblangtag-0.6.4.ebuild')

diff --git a/app-text/liblangtag/liblangtag-0.6.4.ebuild b/app-text/liblangtag/liblangtag-0.6.4.ebuild
new file mode 100644
index 000000000000..ddaae38ff669
--- /dev/null
+++ b/app-text/liblangtag/liblangtag-0.6.4.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Interface library to access tags for identifying languages"
+HOMEPAGE="https://bitbucket.org/tagoh/liblangtag/wiki/Home"
+SRC_URI="https://bitbucket.org/tagoh/${PN}/downloads/${P}.tar.bz2"
+
+LICENSE="|| ( LGPL-3 MPL-2.0 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="debug doc introspection test"
+
+# Upstream expect liblangtag to be installed when one runs tests...
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/libxml2
+	introspection? ( dev-libs/gobject-introspection )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-libs/check )
+"
+BDEPEND="
+	sys-devel/gettext
+	sys-devel/libtool
+	doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection-common )
+"
+
+src_prepare() {
+	default
+	xdg_environment_reset
+	if [[ -d docs/html ]]; then
+		rm -r docs/html || die "Failed to remove existing gtk-doc"
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable test)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}
-- 
cgit v1.2.3