From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 app-text/libetonyek/libetonyek-9999.ebuild | 62 ++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 app-text/libetonyek/libetonyek-9999.ebuild

(limited to 'app-text/libetonyek/libetonyek-9999.ebuild')

diff --git a/app-text/libetonyek/libetonyek-9999.ebuild b/app-text/libetonyek/libetonyek-9999.ebuild
new file mode 100644
index 000000000000..26e021ff6f50
--- /dev/null
+++ b/app-text/libetonyek/libetonyek-9999.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
+[[ ${PV} == 9999 ]] && inherit autotools git-r3
+
+DESCRIPTION="Library parsing Apple Keynote presentations"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libetonyek"
+[[ ${PV} == 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
+
+LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc static-libs test"
+
+RDEPEND="
+	app-text/liblangtag
+	dev-libs/librevenge
+	dev-libs/libxml2
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	>=dev-util/mdds-1.2.2:1
+	media-libs/glm
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cppunit )
+"
+
+pkg_pretend() {
+	if [[ $(gcc-major-version) -lt 4 ]] || {
+		[[ $(gcc-major-version) -eq 4 && $(gcc-minor-version) -lt 8 ]]; }
+	then
+		eerror "Compilation with gcc older than 4.8 is not supported"
+		die "Too old gcc found."
+	fi
+}
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		$(use_with doc docs) \
+		$(use_enable static-libs static) \
+		$(use_enable test tests) \
+		--with-mdds=1.2
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3