From a4e2a46beb5e4858ef27bdedbb0ff6d2ced430ad Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 28 Apr 2018 20:02:04 +0100
Subject: gentoo resync : 28.04.2018

---
 app-text/libetonyek/libetonyek-0.1.8.ebuild | 53 +++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 app-text/libetonyek/libetonyek-0.1.8.ebuild

(limited to 'app-text/libetonyek/libetonyek-0.1.8.ebuild')

diff --git a/app-text/libetonyek/libetonyek-0.1.8.ebuild b/app-text/libetonyek/libetonyek-0.1.8.ebuild
new file mode 100644
index 000000000000..39b6f10a69f8
--- /dev/null
+++ b/app-text/libetonyek/libetonyek-0.1.8.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
+[[ ${PV} == 9999 ]] && inherit autotools git-r3
+
+DESCRIPTION="Library parsing Apple Keynote presentations"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libetonyek"
+[[ ${PV} == 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
+
+LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc static-libs test"
+
+RDEPEND="
+	app-text/liblangtag
+	dev-libs/librevenge
+	dev-libs/libxml2
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	>=dev-util/mdds-1.2.2:1
+	media-libs/glm
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cppunit )
+"
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-werror \
+		$(use_with doc docs) \
+		$(use_enable static-libs static) \
+		$(use_enable test tests) \
+		--with-mdds=1.2
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3