From 4cd2370bed609c118b6edfde5d3f116e5c35b897 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 3 Dec 2017 16:17:22 +0000
Subject: gentoo resync : 03.12.2017

---
 app-text/ansifilter/ansifilter-2.9.ebuild | 57 +++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 app-text/ansifilter/ansifilter-2.9.ebuild

(limited to 'app-text/ansifilter/ansifilter-2.9.ebuild')

diff --git a/app-text/ansifilter/ansifilter-2.9.ebuild b/app-text/ansifilter/ansifilter-2.9.ebuild
new file mode 100644
index 000000000000..a4c7a3b32c73
--- /dev/null
+++ b/app-text/ansifilter/ansifilter-2.9.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs qmake-utils
+
+DESCRIPTION="Handles text files containing ANSI terminal escape codes"
+HOMEPAGE="http://www.andre-simon.de/"
+SRC_URI="http://www.andre-simon.de/zip/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="qt5"
+
+RDEPEND="
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# bug 431452
+	rm src/qt-gui/moc_mydialog.cpp || die
+}
+
+src_configure() {
+	if use qt5 ; then
+		pushd src/qt-gui > /dev/null || die
+		eqmake5
+		popd > /dev/null || die
+	fi
+}
+
+src_compile() {
+	emake -f makefile CC="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS} -DNDEBUG -std=c++11"
+
+	if use qt5 ; then
+		pushd src/qt-gui > /dev/null || die
+		emake
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	dobin src/${PN}
+	use qt5 && dobin src/qt-gui/${PN}-gui
+
+	gunzip man/${PN}.1.gz
+	doman man/${PN}.1
+	einstalldocs
+}
-- 
cgit v1.2.3