From 24fd814c326e282c4321965c31f341dad77e270d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Fri, 8 Jan 2021 11:28:34 +0000
Subject: gentoo resync : 08.01.2021

---
 app-shells/pdmenu/pdmenu-1.3.6.ebuild | 61 +++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 app-shells/pdmenu/pdmenu-1.3.6.ebuild

(limited to 'app-shells/pdmenu/pdmenu-1.3.6.ebuild')

diff --git a/app-shells/pdmenu/pdmenu-1.3.6.ebuild b/app-shells/pdmenu/pdmenu-1.3.6.ebuild
new file mode 100644
index 000000000000..68faa77355e3
--- /dev/null
+++ b/app-shells/pdmenu/pdmenu-1.3.6.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="A simple console menu program"
+HOMEPAGE="http://joeyh.name/code/pdmenu/"
+SRC_URI="https://dev.gentoo.org/~bkohler/dist/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~mips ~x86"
+IUSE="nls gpm examples"
+
+DEPEND="
+	sys-libs/slang
+	gpm? ( sys-libs/gpm )
+	nls? ( sys-devel/gettext )"
+
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-impl-dec.patch
+)
+
+DOCS=( doc/ANNOUNCE doc/BUGS doc/TODO )
+
+src_prepare() {
+	default
+	sed \
+		-e 's:\(-o pdmenu\):$(LDFLAGS) \1:g' \
+		-i Makefile || die
+}
+
+src_configure() {
+	CC=$(tc-getCC) econf \
+		$(use_with gpm) \
+		$(use_enable nls)
+}
+
+src_compile() {
+	emake CC=$(tc-getCC)
+}
+
+src_install() {
+	dobin "${PN}"
+	use examples && dodoc -r examples
+	mv "doc/${PN}.man" "doc/${PN}.1" || die
+	mv "doc/${PN}rc.man" "doc/${PN}rc.5" || die
+	doman "doc/${PN}.1" "doc/${PN}rc.5"
+	einstalldocs
+}
+
+pkg_postinst() {
+	ewarn "Note this part from man page: Security warning! Any exec command"
+	ewarn "that uses the 'edit' flag will be a security hole. The user need"
+	ewarn "only to enter text with a ';' in it, and they can run an"
+	ewarn "arbitrary command after the semicolon!"
+}
-- 
cgit v1.2.3