From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 app-portage/layman/layman-2.2.0-r7.ebuild | 88 +++++++++++++++++++++++++++++++
 1 file changed, 88 insertions(+)
 create mode 100644 app-portage/layman/layman-2.2.0-r7.ebuild

(limited to 'app-portage/layman/layman-2.2.0-r7.ebuild')

diff --git a/app-portage/layman/layman-2.2.0-r7.ebuild b/app-portage/layman/layman-2.2.0-r7.ebuild
new file mode 100644
index 000000000000..c8f4f72e8786
--- /dev/null
+++ b/app-portage/layman/layman-2.2.0-r7.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+PYTHON_COMPAT=( python{2_7,3_4} pypy )
+PYTHON_REQ_USE="xml(+)"
+
+inherit eutils distutils-r1 linux-info prefix
+
+DESCRIPTION="Tool to manage Gentoo overlays"
+HOMEPAGE="http://layman.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bazaar cvs darcs +git g-sorcery mercurial squashfs subversion test"
+
+DEPEND="test? ( dev-vcs/subversion )"
+
+RDEPEND="
+	bazaar? ( dev-vcs/bzr )
+	cvs? ( dev-vcs/cvs )
+	darcs? ( dev-vcs/darcs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	g-sorcery? ( app-portage/g-sorcery )
+	subversion? (
+		|| (
+			>=dev-vcs/subversion-1.5.4[http]
+			>=dev-vcs/subversion-1.5.4[webdav-neon]
+			>=dev-vcs/subversion-1.5.4[webdav-serf]
+		)
+	)
+	sys-apps/portage[${PYTHON_USEDEP}]
+	>=dev-python/ssl-fetch-0.2[${PYTHON_USEDEP}]
+	"
+
+layman_check_kernel_config() {
+	local CONFIG_CHECK
+	use squashfs && CONFIG_CHECK+=" ~BLK_DEV_LOOP ~SQUASHFS"
+	[[ -n ${CONFIG_CHECK} ]] && check_extra_config
+}
+
+pkg_pretend() {
+	layman_check_kernel_config
+}
+
+pkg_setup() {
+	layman_check_kernel_config
+}
+
+python_prepare_all()  {
+	distutils-r1_python_prepare_all
+	epatch "${FILESDIR}"/${P}-removes-doctest-remnants.patch
+	epatch "${FILESDIR}"/${P}-change-for-upstream-ssl-fetch.patch
+	epatch "${FILESDIR}"/${P}-adds-kwargs-debug.patch
+	rm "${S}"/"${PN}"/tests/dtest.py
+	eprefixify etc/layman.cfg layman/config.py
+}
+
+python_test() {
+	for suite in layman/tests/external.py ; do
+		PYTHONPATH="." "${PYTHON}" ${suite} \
+		|| die "test suite '${suite}' failed"
+	done
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/layman
+	doins etc/layman.cfg
+
+	doman doc/layman.8
+	dohtml doc/layman.8.html
+
+	keepdir /var/lib/layman
+	keepdir /etc/layman/overlays
+}
+
+pkg_postinst() {
+	# now run layman's update utility
+	einfo "Running layman-updater..."
+	"${EROOT}"/usr/bin/layman-updater
+	einfo
+}
-- 
cgit v1.2.3