From 3b08f674e3f771b49370edb144dab0958c8cf721 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 31 Aug 2021 08:59:54 +0100
Subject: gentoo resync : 31.08.2021

---
 app-portage/iwdevtools/iwdevtools-0.4.0.ebuild | 43 ++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 app-portage/iwdevtools/iwdevtools-0.4.0.ebuild

(limited to 'app-portage/iwdevtools/iwdevtools-0.4.0.ebuild')

diff --git a/app-portage/iwdevtools/iwdevtools-0.4.0.ebuild b/app-portage/iwdevtools/iwdevtools-0.4.0.ebuild
new file mode 100644
index 000000000000..1152e307b338
--- /dev/null
+++ b/app-portage/iwdevtools/iwdevtools-0.4.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson optfeature
+
+DESCRIPTION="Small tools to aid with Gentoo development, primarily intended for QA"
+HOMEPAGE="https://github.com/ionenwks/iwdevtools"
+SRC_URI="https://github.com/ionenwks/iwdevtools/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-misc/pax-utils
+	app-portage/portage-utils
+	sys-apps/diffutils
+	sys-apps/file
+	sys-apps/portage
+	sys-apps/util-linux"
+BDEPEND="test? ( ${RDEPEND} )"
+
+src_configure() {
+	meson_src_configure -Ddocdir=${PF}
+}
+
+pkg_postinst() {
+	optfeature "detecting potential ABI issues using abidiff" dev-util/libabigail
+
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		elog "To (optionally) integrate with portage, inspect the .bashrc files installed"
+		elog "at ${EROOT}/usr/share/${PN}. If not already using a bashrc, you can use"
+		elog "the example bashrc directly by creating a symlink:"
+		elog
+		elog "    ln -s ../../usr/share/${PN}/bashrc ${EROOT}/etc/portage/bashrc"
+		elog
+		elog "See ${EROOT}/usr/share/doc/${PF}/README.rst* for info on tools."
+	fi
+}
-- 
cgit v1.2.3