From 07e5258263817a33e6c141c7f2626f909688bdb1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Fri, 8 Sep 2023 22:31:44 +0100
Subject: gentoo auto-resync : 08:09:2023 - 22:31:44

---
 app-portage/getuto/getuto-1.7.ebuild | 50 ++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 app-portage/getuto/getuto-1.7.ebuild

(limited to 'app-portage/getuto/getuto-1.7.ebuild')

diff --git a/app-portage/getuto/getuto-1.7.ebuild b/app-portage/getuto/getuto-1.7.ebuild
new file mode 100644
index 000000000000..4778eb372c02
--- /dev/null
+++ b/app-portage/getuto/getuto-1.7.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Stand-alone gentoo install trust anchor generation tool"
+HOMEPAGE="https://github.com/projg2/getuto"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/projg2/getuto"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/projg2/getuto/archive/refs/tags/${P}.tar.gz
+	"
+	S=${WORKDIR}/${PN}-${P}
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+SRC_URI+=" test? ( https://mirror.bytemark.co.uk/gentoo/releases/amd64/binpackages/17.1/x86-64/virtual/libc/libc-1-r1-1.gpkg.tar )"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-crypt/gnupg
+	dev-libs/openssl
+	sec-keys/openpgp-keys-gentoo-release
+	sys-apps/gentoo-functions
+"
+
+src_unpack() {
+	if [[ ${PV} == 9999 ]] ; then
+		git-r3_src_unpack
+	else
+		# Don't mangle test data
+		unpack ${P}.tar.gz
+	fi
+
+	if use test ; then
+		cp "${DISTDIR}"/libc-1-r1-1.gpkg.tar "${S}" || die
+	fi
+}
+
+src_install() {
+	dobin getuto
+}
-- 
cgit v1.2.3