From 4f2d7949f03e1c198bc888f2d05f421d35c57e21 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Mon, 9 Oct 2017 18:53:29 +0100
Subject: reinit the tree, so we can have metadata

---
 app-office/orage/orage-4.12.1-r1.ebuild | 63 +++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 app-office/orage/orage-4.12.1-r1.ebuild

(limited to 'app-office/orage/orage-4.12.1-r1.ebuild')

diff --git a/app-office/orage/orage-4.12.1-r1.ebuild b/app-office/orage/orage-4.12.1-r1.ebuild
new file mode 100644
index 000000000000..e9b09f692ec2
--- /dev/null
+++ b/app-office/orage/orage-4.12.1-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome2-utils
+
+DESCRIPTION="A time managing application (and panel plug-in) for the Xfce desktop environment"
+HOMEPAGE="https://git.xfce.org/apps/orage/"
+SRC_URI="mirror://xfce/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="berkdb +clock-panel-plugin dbus libnotify"
+
+RDEPEND=">=dev-libs/libical-0.48:=
+	dev-libs/popt:=
+	>=x11-libs/gtk+-2.10:2=
+	berkdb? ( >=sys-libs/db-4:= )
+	clock-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+	dbus? ( >=dev-libs/dbus-glib-0.100:= )
+	libnotify? ( >=x11-libs/libnotify-0.7:= )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	>=sys-devel/libtool-2.2.6
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		--libexecdir="${EPREFIX}/usr/$(get_libdir)"
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}/html
+		$(use_enable clock-panel-plugin libxfce4panel)
+		$(use_enable dbus)
+		$(use_enable libnotify)
+		$(use_with berkdb bdb4)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_preinst() {
+	# Replacing directory by symlink is unreliable
+	if [[ -L ${EROOT}/usr/share/orage/doc/C ]]; then
+		rm -f "${EROOT}/usr/share/orage/doc/C" || die
+	fi
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3