From 95461df035e3867364495f065e5e805bf629b2d7 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 26 Oct 2021 00:10:07 +0100
Subject: gentoo resync : 25.10.2021

---
 app-office/mdbtools/mdbtools-1.0.0.ebuild | 58 +++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 app-office/mdbtools/mdbtools-1.0.0.ebuild

(limited to 'app-office/mdbtools/mdbtools-1.0.0.ebuild')

diff --git a/app-office/mdbtools/mdbtools-1.0.0.ebuild b/app-office/mdbtools/mdbtools-1.0.0.ebuild
new file mode 100644
index 000000000000..b81d22dca2c1
--- /dev/null
+++ b/app-office/mdbtools/mdbtools-1.0.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Set of libraries and utilities for reading Microsoft Access database (MDB) files"
+HOMEPAGE="https://github.com/mdbtools/mdbtools"
+SRC_URI="https://github.com/mdbtools/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="glib iconv odbc"
+
+BDEPEND="
+	app-text/txt2man
+	sys-devel/flex
+	virtual/pkgconfig
+	virtual/yacc
+"
+RDEPEND="
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+	glib? ( dev-libs/glib:2 )
+	iconv? ( virtual/libiconv )
+	odbc? ( >=dev-db/unixODBC-2.0 )
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS HACKING NEWS README.md )
+
+src_prepare() {
+	default
+
+	# bug #770019
+	sed -i -e 's/-Werror//' configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+		$(use_enable glib)
+		$(use_enable iconv)
+		$(use odbc && echo "--with-unixodbc=${EPREFIX}/usr")
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3