From d162ba1860a88062f4cd61f8b52fc303ba0b2991 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 7 Aug 2021 00:16:33 +0100
Subject: gentoo resync : 07.08.2021

---
 app-office/mdbtools/mdbtools-0.9.4.ebuild | 59 +++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 app-office/mdbtools/mdbtools-0.9.4.ebuild

(limited to 'app-office/mdbtools/mdbtools-0.9.4.ebuild')

diff --git a/app-office/mdbtools/mdbtools-0.9.4.ebuild b/app-office/mdbtools/mdbtools-0.9.4.ebuild
new file mode 100644
index 000000000000..f23e1aadf9c6
--- /dev/null
+++ b/app-office/mdbtools/mdbtools-0.9.4.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Set of libraries and utilities for reading Microsoft Access database (MDB) files"
+HOMEPAGE="https://github.com/mdbtools/mdbtools"
+SRC_URI="https://github.com/brianb/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="glib odbc"
+
+BDEPEND="
+	app-text/txt2man
+	sys-devel/flex
+	virtual/pkgconfig
+	virtual/yacc
+"
+RDEPEND="
+	sys-libs/ncurses:0=
+	sys-libs/readline:0=
+	virtual/libiconv
+	glib? ( dev-libs/glib:2 )
+	odbc? ( >=dev-db/unixODBC-2.0 )
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS HACKING NEWS README.md )
+
+src_prepare() {
+	default
+
+	# bug #770019
+	sed -i -e 's/-Werror//' configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	# TODO: Make iconv optional
+
+	local myeconfargs=(
+		--disable-static
+		$(use_enable glib)
+		$(use odbc && echo "--with-unixodbc=${EPREFIX}/usr")
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3