From cd0d9000770337b445051f1852fe3971ceb7a6e2 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 18 Mar 2023 18:31:43 +0000
Subject: gentoo auto-resync : 18:03:2023 - 18:31:42

---
 app-misc/tracker/Manifest                |   2 +
 app-misc/tracker/tracker-3.5.0_rc.ebuild | 108 +++++++++++++++++++++++++++++++
 2 files changed, 110 insertions(+)
 create mode 100644 app-misc/tracker/tracker-3.5.0_rc.ebuild

(limited to 'app-misc/tracker')

diff --git a/app-misc/tracker/Manifest b/app-misc/tracker/Manifest
index edc7c061cfeb..0718ed9beb10 100644
--- a/app-misc/tracker/Manifest
+++ b/app-misc/tracker/Manifest
@@ -1,3 +1,5 @@
 DIST tracker-3.4.2.tar.xz 1865236 BLAKE2B 31cdb33de38d9251fc60a71b31c539e3f045748fb5dc160656dd5187dce109da858bad5390864cda8b63466a5113e0a193e0799b662ec250a31cfdff79467e6e SHA512 2214bce7cdbaf1039b11986cf101f615337bbc450331ee703edcfd7ad62dee6e1db831c2c89bf341663cadcdaae6ee9e5a15f49a8087acaafd58b389292ef480
+DIST tracker-3.5.0.rc.tar.xz 1330772 BLAKE2B 27f6b942bb7a26266ede88466cbc1671779d49fa95278b2949d6338f6f976aa83aa15ef79c61f30a3c61b0304aee0ae125253185904794ba566b18397b868988 SHA512 cdbf903900a66ce0115e94193834d800a94d7dc7ff023125a8c1da9bf8d743829633bbe6af748bf0535071e492bd249b37e937527a3039143376511a320ddf44
 EBUILD tracker-3.4.2.ebuild 2719 BLAKE2B fa701f0dc1306fc893e0125bd8502c2724213f4084c902608cffc3f69de3ebb9ba474e8038213d1c847d013cf918bda4ddbc5049e62a21433e2e508308fc8d89 SHA512 0f917521e0e083765cba5ca5e64cad9a98e1b13735523217bee2f97e15a9c27899d675deefa9779e0664fa7ba573c31ed58967a753bb8b26c15a921b62d8cc95
+EBUILD tracker-3.5.0_rc.ebuild 2571 BLAKE2B ec79c514cfa58b64a51213abd77a14763ac4355daa644f866003acb0c78eb628d6ae231e33b0e6b615f8a1761c718f4dbbebc5a13d9d3b19c89e0e333df74a0c SHA512 a621978f3b78ce1c5099dcf6546f9cca1cde39b9a70aaf2b1271d58c3d3f7b53c668a8026886b2ab50091e073493aa8633acf234775719d0e79ce1f6c5ffa5ba
 MISC metadata.xml 586 BLAKE2B 8244e6f8d9491a0c224ed84f17ee6ad64b22e0c373243a319e7911739a7db6223ce47693ed5b31053b4465f35d20108db1469d74afcebb36b4516a53cbd7f98a SHA512 0a60b0e4b077bb03d02b7990511041695c5dff7a8a0972fa80abe9968b643ad5c2ba65182c079e8d5f3d1ef72a2c4dcc659d6ec283bf80813135c94cab2dddef
diff --git a/app-misc/tracker/tracker-3.5.0_rc.ebuild b/app-misc/tracker/tracker-3.5.0_rc.ebuild
new file mode 100644
index 000000000000..4fd068651f29
--- /dev/null
+++ b/app-misc/tracker/tracker-3.5.0_rc.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit bash-completion-r1 flag-o-matic gnome.org gnome2-utils linux-info meson python-any-r1 systemd vala xdg
+
+DESCRIPTION="A tagging metadata database, search tool and indexer"
+HOMEPAGE="https://wiki.gnome.org/Projects/Tracker https://gitlab.gnome.org/GNOME/tracker"
+SRC_URI="https://download.gnome.org/sources/${PN}/3.5/${PN}-3.5.0.rc.tar.xz"
+S="${WORKDIR}/${PN}-3.5.0.rc"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="3/0" # libtracker-sparql-3.0 soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="gtk-doc +miners stemmer test vala"
+RESTRICT="!test? ( test )"
+
+PV_SERIES=$(ver_cut 1-2)
+
+RDEPEND="
+	>=dev-libs/glib-2.52:2
+	>=sys-apps/dbus-1.3.2
+	>=dev-libs/gobject-introspection-1.54:=
+	>=dev-libs/icu-4.8.1.2:=
+	>=dev-libs/json-glib-1.4
+	>=net-libs/libsoup-2.99.2:3.0
+	>=dev-libs/libxml2-2.7
+	>=dev-db/sqlite-3.29.0:3
+	stemmer? ( dev-libs/snowball-stemmer:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	app-text/asciidoc
+	dev-libs/libxslt
+	$(vala_depend)
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+	test? (
+		$(python_gen_any_dep 'dev-python/pygobject[${PYTHON_USEDEP}]')
+		$(python_gen_any_dep 'dev-python/tappy[${PYTHON_USEDEP}]')
+	)
+	${PYTHON_DEPS}
+"
+PDEPEND="miners? ( >=app-misc/tracker-miners-${PV_SERIES} )"
+
+python_check_deps() {
+	python_has_version -b \
+		"dev-python/pygobject[${PYTHON_USEDEP}]" \
+		"dev-python/tappy[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="INOTIFY_USER"
+	linux-info_pkg_setup
+
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	append-cflags -DTRACKER_DEBUG -DG_DISABLE_CAST_CHECKS
+
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dman=true
+		$(meson_feature stemmer)
+		-Dunicode_support=icu
+		-Dbash_completion_dir="$(get_bashcompdir)"
+		-Dsystemd_user_services_dir="$(systemd_get_userunitdir)"
+		$(meson_use test tests)
+		-Dintrospection=enabled
+		$(meson_feature vala vapi)
+		-Dsoup=soup3
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/Tracker-3.0 "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3