From 9ee6d97c2883d42f204a533a8bc1f4562df778fb Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 16 Sep 2020 09:32:48 +0100
Subject: gentoo resync : 16.09.2020

---
 app-misc/qlcplus/qlcplus-4.12.3.ebuild | 65 ++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 app-misc/qlcplus/qlcplus-4.12.3.ebuild

(limited to 'app-misc/qlcplus/qlcplus-4.12.3.ebuild')

diff --git a/app-misc/qlcplus/qlcplus-4.12.3.ebuild b/app-misc/qlcplus/qlcplus-4.12.3.ebuild
new file mode 100644
index 000000000000..6fb4d8a64529
--- /dev/null
+++ b/app-misc/qlcplus/qlcplus-4.12.3.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit qmake-utils udev virtualx xdg
+
+DESCRIPTION="A software to control DMX or analog lighting systems"
+HOMEPAGE="https://www.qlcplus.org/"
+SRC_URI="https://github.com/mcallegari/${PN}/archive/QLC+_${PV}.tar.gz"
+S="${WORKDIR}/qlcplus-QLC-_${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+"
+RDEPEND="
+	dev-embedded/libftdi:=
+	dev-libs/glib:2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[widgets]
+	dev-qt/qtnetwork:5
+	dev-qt/qtscript:5
+	dev-qt/qtwidgets:5
+	media-libs/alsa-lib
+	media-libs/libmad
+	media-libs/libsndfile
+	sci-libs/fftw:3.0
+	virtual/libusb:0
+	virtual/libusb:1
+	virtual/udev
+"
+DEPEND="${RDEPEND}
+	dev-qt/qttest:5
+"
+
+src_prepare() {
+	default
+
+	sed -e "/UDEVRULESDIR/s:/etc/udev/rules.d:$(get_udevdir)/rules.d:" \
+		-i variables.pri || die
+
+	## Remove Werror-flag since there are some warnings with gcc-9.x
+	sed -e "s/QMAKE_CXXFLAGS += -Werror/#&/g" \
+		-i variables.pri || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}
+
+src_test() {
+	virtx emake check
+}
-- 
cgit v1.2.3