From 068424b26532f3551a81421a9be67ed206e5c11a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Wed, 11 Aug 2021 07:02:28 +0100
Subject: gentoo resync : 11.08.2021

---
 app-misc/libdatovka/libdatovka-0.1.2.ebuild | 55 +++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 app-misc/libdatovka/libdatovka-0.1.2.ebuild

(limited to 'app-misc/libdatovka/libdatovka-0.1.2.ebuild')

diff --git a/app-misc/libdatovka/libdatovka-0.1.2.ebuild b/app-misc/libdatovka/libdatovka-0.1.2.ebuild
new file mode 100644
index 000000000000..456af2ddfada
--- /dev/null
+++ b/app-misc/libdatovka/libdatovka-0.1.2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Client library for accessing ISDS SOAP services"
+HOMEPAGE="https://www.datovka.cz/cs/pages/libdatovka.html"
+SRC_URI="https://secure.nic.cz/files/datove_schranky/${PN}/${P}.tar.xz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="+curl debug doc nls openssl test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/libxml2
+	curl? ( net-misc/curl[ssl] )
+	doc? (
+		app-text/docbook-xsl-stylesheets
+		dev-libs/libxslt
+	)
+	openssl? ( dev-libs/openssl:= )
+	!openssl? (
+		app-crypt/gnupg
+		app-crypt/gpgme
+		dev-libs/libgcrypt:=
+	)"
+DEPEND="${RDEPEND}
+	test? ( net-libs/gnutls )"
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_configure() {
+	local myeconfargs=(
+		--disable-fatalwarnings
+		--disable-static
+		$(use_with curl libcurl)
+		$(use_enable curl curlreauthorizationbug)
+		$(use_enable doc)
+		$(use_enable debug)
+		$(use_enable nls)
+		$(use_enable openssl openssl-backend)
+		$(use_enable test)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3