From fbba40085f5d1591a67b49f5aa48b4071b7560f1 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 10 Jun 2023 21:52:51 +0100
Subject: gentoo auto-resync : 10:06:2023 - 21:52:51

---
 app-misc/jdupes/jdupes-1.23.0.ebuild | 47 ++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 app-misc/jdupes/jdupes-1.23.0.ebuild

(limited to 'app-misc/jdupes/jdupes-1.23.0.ebuild')

diff --git a/app-misc/jdupes/jdupes-1.23.0.ebuild b/app-misc/jdupes/jdupes-1.23.0.ebuild
new file mode 100644
index 000000000000..86270d6d71e7
--- /dev/null
+++ b/app-misc/jdupes/jdupes-1.23.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Identify duplicate files on the filesystem"
+HOMEPAGE="https://github.com/jbruchon/jdupes"
+if [[ "${PV}" == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/jbruchon/jdupes.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/jbruchon/jdupes/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+LICENSE="MIT"
+SLOT="0"
+
+DEPEND="dev-libs/libjodycode"
+RDEPEND="${DEPEND}"
+
+IUSE="+dedupe lowmem hardened"
+
+# missing test.sh script
+# https://github.com/jbruchon/jdupes/issues/191
+RESTRICT="test"
+
+src_prepare() {
+	sed -i -e '/PREFIX/s/=/?=/' Makefile || die
+	default
+}
+
+src_compile() {
+	tc-export CC
+	local myconf=(
+		$(usex dedupe 'ENABLE_DEDUPE=1' '')
+		$(usex lowmem 'LOW_MEMORY=1' '')
+		$(usex hardened 'HARDEN=1' '')
+	)
+	emake ${myconf[@]}
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+	einstalldocs
+}
-- 
cgit v1.2.3