From 2771f79232c273bc2a57d23bf335dd81ccf6af28 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sun, 5 Dec 2021 02:47:11 +0000
Subject: gentoo resync : 05.12.2021

---
 app-misc/golly/golly-4.1-r1.ebuild | 67 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 app-misc/golly/golly-4.1-r1.ebuild

(limited to 'app-misc/golly/golly-4.1-r1.ebuild')

diff --git a/app-misc/golly/golly-4.1-r1.ebuild b/app-misc/golly/golly-4.1-r1.ebuild
new file mode 100644
index 000000000000..b502a58b492a
--- /dev/null
+++ b/app-misc/golly/golly-4.1-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+WX_GTK_VER=3.0-gtk3
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit desktop python-single-r1 toolchain-funcs wxwidgets xdg
+
+DESCRIPTION="simulator for Conway's Game of Life and other cellular automata"
+HOMEPAGE="http://golly.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.gz"
+S="${WORKDIR}/${P}-src"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/wxGTK:${WX_GTK_VER}[X,opengl,sdl,tiff]
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/${PN}-4.0-CFLAGS.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	setup-wxwidgets
+}
+
+src_compile() {
+	local mymakeopts=(
+		ENABLE_SOUND=yes
+		GOLLYDIR="${EPREFIX}/usr/share/${PN}"
+		PYTHON=${EPYTHON}
+		WX_CONFIG=${WX_CONFIG}
+		AR=$(tc-getAR)
+		CC=$(tc-getCC)
+		CXX=$(tc-getCXX)
+		CXXC=$(tc-getCXX)
+		RANLIB=$(tc-getRANLIB)
+	)
+	emake -C gui-wx -f makefile-gtk "${mymakeopts[@]}"
+}
+
+src_install() {
+	# has no 'make install' Let's install files manually.
+	dobin golly bgolly
+	insinto /usr/share/${PN}
+	doins -r Help Patterns Scripts Rules docs
+
+	newicon --size 32 gui-wx/icons/appicon.xpm ${PN}.xpm
+	make_desktop_entry ${PN} "Golly" ${PN} "Science"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3