From 05b8b0e0af1d72e51a3ee61522941bf7605cd01c Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 4 Jul 2020 14:05:23 +0100
Subject: gentoo resync : 04.07.2020

---
 app-misc/golly/golly-3.3-r3.ebuild | 70 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 app-misc/golly/golly-3.3-r3.ebuild

(limited to 'app-misc/golly/golly-3.3-r3.ebuild')

diff --git a/app-misc/golly/golly-3.3-r3.ebuild b/app-misc/golly/golly-3.3-r3.ebuild
new file mode 100644
index 000000000000..10240aa63d7d
--- /dev/null
+++ b/app-misc/golly/golly-3.3-r3.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+WX_GTK_VER=3.0-gtk3
+PYTHON_COMPAT=( python{2_7,3_{7,8,9}} )
+
+inherit autotools desktop python-single-r1 wxwidgets xdg-utils
+
+DESCRIPTION="simulator for Conway's Game of Life and other cellular automata"
+HOMEPAGE="http://golly.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="tiff"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="virtual/opengl
+	sys-libs/zlib
+	x11-libs/wxGTK:${WX_GTK_VER}[X,opengl,tiff?]
+	${PYTHON_DEPS}
+"
+
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${P}-src
+
+PATCHES=(
+	"${FILESDIR}"/${P}-nondynamic-python.patch
+	"${FILESDIR}"/${P}-allow-py23-exec.patch
+	"${FILESDIR}"/${P}-glife-py23.patch
+	"${FILESDIR}"/${P}-allow-py3.patch
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	setup-wxwidgets
+}
+
+src_prepare() {
+	default
+
+	# patches change configure.ac and Makefile.am
+	pushd gui-wx/configure
+		eautoreconf
+	popd
+}
+
+src_configure() {
+	ECONF_SOURCE=gui-wx/configure econf \
+		--with-wxshared
+}
+
+src_install() {
+	emake docdir= DESTDIR="${D}" install
+	dodoc docs/ReadMe.html
+	newicon --size 32 gui-wx/icons/appicon.xpm ${PN}.xpm
+	make_desktop_entry ${PN} "Golly" ${PN} "Science"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3