From 2719f73b6813d11d13a9650cdd2ab8ec6e69385d Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Sat, 9 Jul 2022 15:43:36 +0100
Subject: gentoo resync : 09.07.2022

---
 app-misc/ckb/ckb-9999.ebuild | 73 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 app-misc/ckb/ckb-9999.ebuild

(limited to 'app-misc/ckb/ckb-9999.ebuild')

diff --git a/app-misc/ckb/ckb-9999.ebuild b/app-misc/ckb/ckb-9999.ebuild
new file mode 100644
index 000000000000..4629a34e2bd8
--- /dev/null
+++ b/app-misc/ckb/ckb-9999.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake udev xdg
+
+DESCRIPTION="Corsair K65/K70/K95 Driver"
+HOMEPAGE="https://github.com/ckb-next/ckb-next"
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ckb-next/ckb-next.git"
+else
+	SRC_URI="https://github.com/ckb-next/ckb-next/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}-next-${PV}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="systemd"
+
+RDEPEND="
+	dev-libs/libdbusmenu-qt
+	dev-libs/quazip:0=
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	|| (
+		media-sound/pulseaudio
+		media-sound/apulse[sdk]
+	)
+	virtual/libudev:=
+	x11-libs/libX11
+	x11-libs/libxcb:=
+	x11-libs/xcb-util-wm"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-qt/linguist-tools:5"
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_UPDATER=yes
+		-DFORCE_INIT_SYSTEM=$(usex systemd systemd openrc)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	dodoc CHANGELOG.md
+}
+
+pkg_postinst() {
+	udev_reload
+
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "The ckb daemon will have to be started before use:"
+		elog
+			if use systemd ; then
+			elog "# systemctl start ckb-next-daemon"
+		else
+			elog "# rc-config start ckb-next-daemon"
+		fi
+	fi
+}
+
+pkg_postrm() {
+	udev_reload
+}
-- 
cgit v1.2.3