From 44cec61076bf2bbb3cea1fc89943dd6818a5acc5 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 6 Jun 2024 00:07:58 +0100
Subject: gentoo auto-resync : 06:06:2024 - 00:07:57

---
 app-i18n/ibus-hangul/ibus-hangul-1.5.5.ebuild | 65 +++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 app-i18n/ibus-hangul/ibus-hangul-1.5.5.ebuild

(limited to 'app-i18n/ibus-hangul/ibus-hangul-1.5.5.ebuild')

diff --git a/app-i18n/ibus-hangul/ibus-hangul-1.5.5.ebuild b/app-i18n/ibus-hangul/ibus-hangul-1.5.5.ebuild
new file mode 100644
index 000000000000..3d3cbefc5d2e
--- /dev/null
+++ b/app-i18n/ibus-hangul/ibus-hangul-1.5.5.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..12} )
+
+inherit autotools gnome2-utils python-single-r1 xdg virtualx
+
+DESCRIPTION="Korean Hangul engine for IBus"
+HOMEPAGE="https://github.com/libhangul/ibus-hangul/wiki"
+SRC_URI="https://github.com/libhangul/${PN}/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	>=app-i18n/libhangul-0.1
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/gettext
+	virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${PN}-test.patch )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		--with-python=${EPYTHON}
+}
+
+src_test() {
+	"${BROOT}"${GLIB_COMPILE_SCHEMAS} --allow-any-name "${S}"/data || die
+
+	export GSETTINGS_BACKEND="memory"
+	export GSETTINGS_SCHEMA_DIR="${S}/data"
+	virtx default
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3