From cf7807d7aea23a99a144afceaba961cfed652b5f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Tue, 11 Mar 2025 01:49:36 +0000
Subject: gentoo auto-resync : 11:03:2025 - 01:49:36
---
app-emulation/Manifest.gz | Bin 15492 -> 15485 bytes
app-emulation/libvirt/Manifest | 5 +-
app-emulation/libvirt/libvirt-11.1.0.ebuild | 381 ++++++++++++++++++++++++++++
app-emulation/libvirt/libvirt-9999.ebuild | 2 +-
4 files changed, 386 insertions(+), 2 deletions(-)
create mode 100644 app-emulation/libvirt/libvirt-11.1.0.ebuild
(limited to 'app-emulation')
diff --git a/app-emulation/Manifest.gz b/app-emulation/Manifest.gz
index 02e937bb1e5f..32471be6832c 100644
Binary files a/app-emulation/Manifest.gz and b/app-emulation/Manifest.gz differ
diff --git a/app-emulation/libvirt/Manifest b/app-emulation/libvirt/Manifest
index f098921f5fcd..37e0bca95e5c 100644
--- a/app-emulation/libvirt/Manifest
+++ b/app-emulation/libvirt/Manifest
@@ -26,11 +26,14 @@ DIST libvirt-10.8.0.tar.xz 9575348 BLAKE2B fb7d7b6d8a158c0045bb7fae4080cf8d58f8f
DIST libvirt-10.8.0.tar.xz.asc 833 BLAKE2B 25b01613df138dbaa921bfe3d3a2384182d4bff1a5828d0b9cccb08e4a48465d0b89391f83824889052e7827b107304289a3a38589039a302c93a15a5d4fe169 SHA512 1099f61b835351165bfa203f3d7d485f16b89e29234a6301e50cf3b5e47e4c7edb9808c23a6fd5045ed44d8349e78596923ea7cc1896e8239b5816e871fdc0cc
DIST libvirt-11.0.0.tar.xz 9700388 BLAKE2B 0fc248bfcc505e143fa56560a216ed62ddeb8f8def5eaf32772bc5f0c1ca87f92dc530d9290f6349dc8727590f6148ffb6627e119f1e89fb0e151f1e6346b645 SHA512 ac5fd17d3f488c241017d967364e0441373e9ab0457dab1acfe84fd0b90353dc5d185cc7fcd2b0d7995af4137a3fa18371abb5511686456a9e720f7ec7829da9
DIST libvirt-11.0.0.tar.xz.asc 833 BLAKE2B c959800b18ac7220970d6a772aefe4a5b53419298641b4fc659db2585d187701b823cda06ea2e16ff8bfa50c7552fb3eb50ff5c4ea40fb4a3c6eb93921481165 SHA512 7b1bb3d902986bc269bf9efd0ab2dbfb256c3e02e0d410e3bf81ddb649b1d0983090adc1857d59db79fa7ac19b983496a80ac3bf6ae13163bb772cea05b5728b
+DIST libvirt-11.1.0.tar.xz 9775904 BLAKE2B 81ce8d537d6d069d44b3e24f2091729acd8b04ceea14e5c56188cffa300015aa5215fa64324718cede93d1bf84ae5409936bf7f6c8505b071b8dcc47094da78c SHA512 f491b3c0b0e4b6a96456eba26d72e820141c231fa44f34f2d153b805b046ca869b5d0286cd7e2867ae938e5eab5e04f2995c097d41227914bc87a76800e89bc8
+DIST libvirt-11.1.0.tar.xz.asc 833 BLAKE2B c1d580c77a336eb83fcc47fd12e0595952612cdb6765adb7c1bb8708457642799833fb7082410198ccf9f22c82714ec0cb288045e0ad4fefdff219b259815b15 SHA512 914237e6341f6df60f407d5e47d4ae1193a75fee905d9faa4a439eda421e446c84909d08b21927b41e0972c90c0eeecb4821fefefcf454872e2887ce91344be3
EBUILD libvirt-10.10.0-r1.ebuild 10172 BLAKE2B 4fcfec9ef56ba146955ba821f8badbc1de0350a88b216a6e705a3d15546f52cb083a9aac612ae5ab3d6ab38eb0b4d12be7c9965084c3c213ad9f86a74b1e3258 SHA512 92d179c3fc9d0ed53d83f930a107081e62c67efab1ff136adc3332a080d4ce3aea9d93c332ee32406804a99ee3bad4951b7408292770bd0c21911d73f2008c81
EBUILD libvirt-10.3.0-r4.ebuild 10193 BLAKE2B 01515dc6f7d77c235b2be818a8f27af6996282cf08d33d57bd84f9a2d3b12ff82082883123d88fc13d6cb8a249c2986ee888e11ab3a9be9de29c24940b6d8352 SHA512 a56a13ce5165a300849708ac6052fbf6703fe0d6db0f05101679f628f43f9e14289e7e3d303f8e0dd66b74160926e32624797df6048e137d88c8fe3b2abcee3f
EBUILD libvirt-10.5.0-r2.ebuild 10075 BLAKE2B 2093b04c2cd3690694d250e9435fe7222e88320f4e21384a11e62bf015f3a0636fadb39e040b87d3e62b1cc343dd09abb3d661912fa0ff9188f8dfdb512ec887 SHA512 0e1c5927c420dcc26f2bdb165112bb7d559a7c4f045ce582e0ed001028b1bbe186646d8b1301abfaa06aeeed65773ed14654bd0277c3dd7cbeeb39ebde87c0d8
EBUILD libvirt-10.6.0-r1.ebuild 10075 BLAKE2B 2093b04c2cd3690694d250e9435fe7222e88320f4e21384a11e62bf015f3a0636fadb39e040b87d3e62b1cc343dd09abb3d661912fa0ff9188f8dfdb512ec887 SHA512 0e1c5927c420dcc26f2bdb165112bb7d559a7c4f045ce582e0ed001028b1bbe186646d8b1301abfaa06aeeed65773ed14654bd0277c3dd7cbeeb39ebde87c0d8
EBUILD libvirt-10.8.0.ebuild 10072 BLAKE2B b3b6dd462d2c817a03a63ac2017b3d157ffc8334c20ac579a013bd59de99b0764358149d2853d421244eec5e6aa4e91ba40864f84c4d1afe4cba78c8aef55f77 SHA512 f1d8c447a8c4933be27e20260add44c66046743739f98fa3502ce3e942da61acb0258438c12d165bdd3e4783ab01bc40e9b86bf7ecc2c8aa7a6305390b4c51b2
EBUILD libvirt-11.0.0.ebuild 10088 BLAKE2B cd8d867441289e994ae329426272bdbf49ed4d79e8145556c2b168fc7a1c07c4242ca7969359eca74e5ad8f4caa837dd517d28a7c11fb4cb60a04e455289ff5a SHA512 c50841c8dc8a7eb3cd0ab543f4a15098707729e2ff3c531bc9e3efaf8efa2d8ef8ac7f58858d43d228bff46768d237077454cde4adf7fc6d048dae1eb1f1e57b
-EBUILD libvirt-9999.ebuild 9809 BLAKE2B 6537162426a467e23f1b6db240f2595a74a3ebaa336d41a087ab868d55327268731b2c163614e7942765e62c1a067eebd92796f99f655689c9c9c96e52b6c540 SHA512 a52eb3c5332f0d446cc989272b04c89f9049c9fa8a7279cb2ce7da7b46f4c3f2b3a09944acf42aa5480d616021eca5bbf0998300758d641c3bc76ff4a21e3568
+EBUILD libvirt-11.1.0.ebuild 9809 BLAKE2B 40b5a8069907614a504a2d6d718c3b4a190d6999ee8f0aafed0fbe3c5d01e142e4bc5958a76d5a69ef5a4a8a683027cc4e0dd5c9e51c4ed79e2e0ca49b503a71 SHA512 7122fce57ffb212382a4724d869a67b050341792c146b18fab7c7bb22ef7830c863234a7f36f05f1378c35649e9b38eeab779b797a6a2d656fffa5b649c19a21
+EBUILD libvirt-9999.ebuild 9809 BLAKE2B 40b5a8069907614a504a2d6d718c3b4a190d6999ee8f0aafed0fbe3c5d01e142e4bc5958a76d5a69ef5a4a8a683027cc4e0dd5c9e51c4ed79e2e0ca49b503a71 SHA512 7122fce57ffb212382a4724d869a67b050341792c146b18fab7c7bb22ef7830c863234a7f36f05f1378c35649e9b38eeab779b797a6a2d656fffa5b649c19a21
MISC metadata.xml 3822 BLAKE2B badb40564def06854a0c3af011b5de2888d722996c9b15df570a709161e49796f3d76ba2365c4adc1724f16bee3518d0e87ed6d2619d505b5ba2f1fd02c90f34 SHA512 f31e86b4d0c1faaf5bf0ac253cf20ce7728b94841debb590356efc0fa1e1a3d095a94e69ce0a34f793faadf10ed00ae1212aac54d13288f1975db4f032fd8b50
diff --git a/app-emulation/libvirt/libvirt-11.1.0.ebuild b/app-emulation/libvirt/libvirt-11.1.0.ebuild
new file mode 100644
index 000000000000..78840580fa60
--- /dev/null
+++ b/app-emulation/libvirt/libvirt-11.1.0.ebuild
@@ -0,0 +1,381 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Packages which get releases together:
+# app-emacs/nxml-libvirt-schemas
+# dev-python/libvirt-python
+# dev-perl/Sys-Virt
+# app-emulation/libvirt
+# Please bump them together!
+
+PYTHON_COMPAT=( python3_{10..13} )
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/libvirt.org.asc
+inherit meson linux-info python-any-r1 readme.gentoo-r1 tmpfiles verify-sig
+
+if [[ ${PV} = *9999* ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt.git"
+ EGIT_BRANCH="master"
+else
+ SRC_URI="https://download.libvirt.org/${P}.tar.xz
+ verify-sig? ( https://download.libvirt.org/${P}.tar.xz.asc )"
+ KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="C toolkit to manipulate virtual machines"
+HOMEPAGE="https://www.libvirt.org/ https://gitlab.com/libvirt/libvirt/"
+LICENSE="LGPL-2.1"
+SLOT="0/${PV}"
+IUSE="
+ apparmor audit bash-completion +caps dtrace firewalld fuse glusterfs
+ iscsi iscsi-direct +libvirtd lvm libssh libssh2 lxc nbd nfs nls numa
+ openvz parted pcap policykit +qemu rbd sasl selinux test +udev
+ virtiofsd virtualbox +virt-network wireshark-plugins xen zfs
+"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+ firewalld? ( virt-network )
+ libvirtd? ( || ( lxc openvz qemu virtualbox xen ) )
+ lxc? ( caps libvirtd )
+ openvz? ( libvirtd )
+ qemu? ( libvirtd )
+ virt-network? ( libvirtd )
+ virtualbox? ( libvirtd )
+ xen? ( libvirtd )"
+
+BDEPEND="
+ app-text/xhtml1
+ dev-lang/perl
+ dev-libs/libxslt
+ dev-perl/XML-XPath
+ dev-python/docutils
+ virtual/pkgconfig
+ bash-completion? ( >=app-shells/bash-completion-2.0 )
+ verify-sig? ( sec-keys/openpgp-keys-libvirt )"
+
+# gettext.sh command is used by the libvirt command wrappers, and it's
+# non-optional, so put it into RDEPEND.
+# We can use both libnl:1.1 and libnl:3, but if you have both installed, the
+# package will use 3 by default. Since we don't have slot pinning in an API,
+# we must go with the most recent.
+RDEPEND="
+ acct-user/qemu
+ app-misc/scrub
+ >=dev-libs/glib-2.66.0
+ dev-libs/libgcrypt
+ dev-libs/libnl:3
+ >=dev-libs/libxml2-2.9.1
+ >=net-analyzer/openbsd-netcat-1.105-r1
+ >=net-libs/gnutls-3.2.0:=
+ net-libs/libtirpc:=
+ >=net-misc/curl-7.18.0
+ sys-apps/dbus
+ sys-apps/dmidecode
+ sys-devel/gettext
+ >=sys-libs/readline-7.0:=
+ virtual/acl
+ apparmor? ( sys-libs/libapparmor )
+ audit? ( sys-process/audit )
+ caps? ( sys-libs/libcap-ng )
+ dtrace? ( dev-debug/systemtap )
+ firewalld? ( >=net-firewall/firewalld-0.6.3 )
+ fuse? ( sys-fs/fuse:= )
+ glusterfs? ( >=sys-cluster/glusterfs-3.4.1 )
+ iscsi? ( >=sys-block/open-iscsi-1.18.0 )
+ iscsi-direct? ( >=net-libs/libiscsi-1.18.0 )
+ libssh? ( >=net-libs/libssh-0.8.1:= )
+ libssh2? ( >=net-libs/libssh2-1.3 )
+ lvm? ( >=sys-fs/lvm2-2.02.48-r2[lvm] )
+ lxc? ( !sys-apps/systemd[cgroup-hybrid(-)] )
+ nbd? (
+ sys-block/nbdkit
+ sys-libs/libnbd
+ )
+ nfs? ( net-fs/nfs-utils )
+ numa? (
+ >sys-process/numactl-2.0.2
+ sys-process/numad
+ )
+ parted? (
+ >=sys-block/parted-1.8[device-mapper]
+ sys-fs/lvm2[lvm]
+ )
+ pcap? ( >=net-libs/libpcap-1.8.0 )
+ policykit? (
+ acct-group/libvirt
+ >=sys-auth/polkit-0.9
+ )
+ qemu? (
+ >=app-emulation/qemu-4.2
+ app-crypt/swtpm
+ dev-libs/json-c:=
+ )
+ rbd? ( sys-cluster/ceph )
+ sasl? ( >=dev-libs/cyrus-sasl-2.1.26 )
+ selinux? ( >=sys-libs/libselinux-2.0.85 )
+ virt-network? (
+ net-dns/dnsmasq[dhcp,ipv6(+),script]
+ net-firewall/ebtables
+ || (
+ >=net-firewall/iptables-1.4.10[ipv6(+)]
+ net-firewall/nftables
+ )
+ net-misc/radvd
+ sys-apps/iproute2[-minimal]
+ )
+ virtiofsd? ( app-emulation/virtiofsd )
+ virtualbox? ( <app-emulation/virtualbox-7.1.0 )
+ wireshark-plugins? ( >=net-analyzer/wireshark-2.6.0:= )
+ xen? (
+ >=app-emulation/xen-4.9.0
+ app-emulation/xen-tools:=
+ )
+ udev? (
+ virtual/libudev:=
+ >=x11-libs/libpciaccess-0.10.9
+ )
+ zfs? ( sys-fs/zfs )
+ kernel_linux? ( sys-apps/util-linux )"
+DEPEND="
+ ${BDEPEND}
+ ${RDEPEND}
+ ${PYTHON_DEPS}
+ test? (
+ $(python_gen_any_dep '
+ dev-python/pytest[${PYTHON_USEDEP}]
+ ')
+ )
+"
+# The 'circular' dependency on dev-python/libvirt-python is because of
+# virt-qemu-qmp-proxy.
+PDEPEND="
+ qemu? ( dev-python/libvirt-python )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-11.0.0-Fix-paths-in-libvirt-guests.sh.in.patch
+ "${FILESDIR}"/${PN}-9.9.0-do-not-use-sysconfig.patch
+ "${FILESDIR}"/${PN}-10.7.0-fix-paths-for-apparmor.patch
+)
+
+python_check_deps() {
+ if use test; then
+ python_has_version -d "dev-python/pytest[${PYTHON_USEDEP}]"
+ fi
+}
+
+pkg_setup() {
+ # Check kernel configuration:
+ CONFIG_CHECK=""
+ use fuse && CONFIG_CHECK+="
+ ~FUSE_FS"
+
+ use lvm && CONFIG_CHECK+="
+ ~BLK_DEV_DM
+ ~DM_MULTIPATH
+ ~DM_SNAPSHOT"
+
+ use lxc && CONFIG_CHECK+="
+ ~BLK_CGROUP
+ ~CGROUP_CPUACCT
+ ~CGROUP_DEVICE
+ ~CGROUP_FREEZER
+ ~CGROUP_NET_PRIO
+ ~CGROUP_PERF
+ ~CGROUPS
+ ~CGROUP_SCHED
+ ~CPUSETS
+ ~IPC_NS
+ ~MACVLAN
+ ~NAMESPACES
+ ~NET_CLS_CGROUP
+ ~NET_NS
+ ~PID_NS
+ ~POSIX_MQUEUE
+ ~SECURITYFS
+ ~USER_NS
+ ~UTS_NS
+ ~VETH
+ ~!GRKERNSEC_CHROOT_MOUNT
+ ~!GRKERNSEC_CHROOT_DOUBLE
+ ~!GRKERNSEC_CHROOT_PIVOT
+ ~!GRKERNSEC_CHROOT_CHMOD
+ ~!GRKERNSEC_CHROOT_CAPS"
+
+ use virt-network && CONFIG_CHECK+="
+ ~BRIDGE_EBT_MARK_T
+ ~BRIDGE_NF_EBTABLES
+ ~NETFILTER_ADVANCED
+ ~NETFILTER_XT_CONNMARK
+ ~NETFILTER_XT_MARK
+ ~NETFILTER_XT_TARGET_CHECKSUM
+ ~NETFILTER_XT_TARGET_MASQUERADE
+ ~NET_ACT_CSUM
+ ~IP_NF_FILTER
+ ~IP_NF_MANGLE
+ ~IP_NF_NAT
+ ~IP6_NF_FILTER
+ ~IP6_NF_MANGLE
+ ~IP6_NF_NAT"
+
+ # Bandwidth Limiting Support
+ use virt-network && CONFIG_CHECK+="
+ ~BRIDGE_EBT_T_NAT
+ ~IP_NF_TARGET_REJECT
+ ~NET_ACT_POLICE
+ ~NET_CLS_FW
+ ~NET_CLS_U32
+ ~NET_SCH_HTB
+ ~NET_SCH_INGRESS
+ ~NET_SCH_SFQ"
+
+ ERROR_USER_NS="Optional depending on LXC configuration."
+
+ if [[ -n ${CONFIG_CHECK} ]]; then
+ linux-info_pkg_setup
+ fi
+
+ python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ touch "${S}/.mailmap" || die
+
+ default
+ python_fix_shebang .
+
+ # Skip fragile tests which relies on pristine environment
+ # (Breaks because of sandbox environment variables)
+ # bug #802876
+ sed -i -e "/commandtest/d" tests/meson.build || die
+
+ # Tweak the init script:
+ cp "${FILESDIR}/libvirtd.init-r19" "${S}/libvirtd.init" || die
+ sed -e "s/USE_FLAG_FIREWALLD/$(usex firewalld 'need firewalld' '')/" \
+ -i "${S}/libvirtd.init" || die "sed failed"
+}
+
+src_configure() {
+ local emesonargs=(
+ $(meson_feature apparmor)
+ $(meson_feature apparmor apparmor_profiles)
+ $(meson_feature audit)
+ $(meson_feature caps capng)
+ $(meson_feature dtrace)
+ $(meson_feature firewalld)
+ $(meson_feature fuse)
+ $(meson_feature glusterfs)
+ $(meson_feature glusterfs storage_gluster)
+ $(meson_feature iscsi storage_iscsi)
+ $(meson_feature iscsi-direct storage_iscsi_direct)
+ $(meson_feature libvirtd driver_libvirtd)
+ $(meson_feature libssh)
+ $(meson_feature libssh2)
+ $(meson_feature lvm storage_lvm)
+ $(meson_feature lvm storage_mpath)
+ $(meson_feature lxc driver_lxc)
+ $(meson_feature nbd nbdkit)
+ $(meson_feature nls)
+ $(meson_feature numa numactl)
+ $(meson_feature numa numad)
+ $(meson_feature openvz driver_openvz)
+ $(meson_feature parted storage_disk)
+ $(meson_feature pcap libpcap)
+ $(meson_feature policykit polkit)
+ $(meson_feature qemu driver_qemu)
+ $(meson_feature qemu json_c)
+ $(meson_feature rbd storage_rbd)
+ $(meson_feature sasl)
+ $(meson_feature selinux)
+ $(meson_feature test tests)
+ $(meson_feature udev)
+ $(meson_feature virt-network driver_network)
+ $(meson_feature virtualbox driver_vbox)
+ $(meson_feature wireshark-plugins wireshark_dissector)
+ $(meson_feature xen driver_libxl)
+ $(meson_feature zfs storage_zfs)
+
+ -Dnetcf=disabled
+ -Dsanlock=disabled
+ -Dopenwsman=disabled
+
+ -Ddriver_esx=enabled
+ -Dinit_script=systemd
+ -Dqemu_user=$(usex caps qemu root)
+ -Dqemu_group=$(usex caps qemu root)
+ -Ddriver_remote=enabled
+ -Dstorage_fs=enabled
+ -Ddriver_vmware=enabled
+
+ --localstatedir="${EPREFIX}/var"
+ -Dinitconfdir="${EPREFIX}/etc/systemd"
+ -Drunstatedir="${EPREFIX}/run"
+ -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+ )
+
+ # Workaround for bug #938302
+ if use dtrace && has_version "dev-debug/systemtap[-dtrace-symlink(+)]" ; then
+ local native_file="${T}"/meson.${CHOST}.ini.local
+ cat >> ${native_file} <<-EOF || die
+ [binaries]
+ dtrace='stap-dtrace'
+ EOF
+ emesonargs+=( --native-file "${native_file}" )
+ fi
+
+ meson_src_configure
+}
+
+src_test() {
+ export VIR_TEST_DEBUG=1
+ # Don't run the syntax check tests, they're fragile and not relevant
+ # to us downstream anyway.
+ # We also crank up the timeout (as Fedora does) just to preempt failures
+ # on slower arches.
+ meson_src_test --no-suite syntax-check --timeout-multiplier 10
+}
+
+src_install() {
+ meson_src_install
+
+ # Depending on configuration option, libvirt will create some bogus
+ # directoreis. They are either not used, or libvirtd is able to create
+ # them on demand, so let's remove them.
+ #
+ # Note, we are using -f here so that rm does not fail or warn if the
+ # directory is nonexistent.
+ rm -rf "${D}"/etc/sysconfig
+ rm -rf "${D}"/var
+ rm -rf "${D}"/run
+
+ use libvirtd || return 0
+ # From here, only libvirtd-related instructions, be warned!
+
+ newtmpfiles "${FILESDIR}"/libvirtd.tmpfiles.conf libvirtd.conf
+
+ newinitd "${S}/libvirtd.init" libvirtd
+ newinitd "${FILESDIR}/libvirt-guests.init-r4" libvirt-guests
+ newinitd "${FILESDIR}/virtlockd.init-r2" virtlockd
+ newinitd "${FILESDIR}/virtlogd.init-r2" virtlogd
+
+ newconfd "${FILESDIR}/libvirtd.confd-r5" libvirtd
+ newconfd "${FILESDIR}/libvirt-guests.confd" libvirt-guests
+
+ DOC_CONTENTS=$(<"${FILESDIR}/README.gentoo-r3")
+ DISABLE_AUTOFORMATTING=true
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+ touch "${ROOT}"/etc/libvirt/qemu/networks/default.xml || die
+ fi
+
+ use libvirtd || return 0
+ # From here, only libvirtd-related instructions, be warned!
+ tmpfiles_process libvirtd.conf
+ readme.gentoo_print_elog
+}
diff --git a/app-emulation/libvirt/libvirt-9999.ebuild b/app-emulation/libvirt/libvirt-9999.ebuild
index 28c7fc107ed5..78840580fa60 100644
--- a/app-emulation/libvirt/libvirt-9999.ebuild
+++ b/app-emulation/libvirt/libvirt-9999.ebuild
@@ -64,7 +64,7 @@ BDEPEND="
RDEPEND="
acct-user/qemu
app-misc/scrub
- >=dev-libs/glib-2.56.0
+ >=dev-libs/glib-2.66.0
dev-libs/libgcrypt
dev-libs/libnl:3
>=dev-libs/libxml2-2.9.1
--
cgit v1.2.3