From c107831b9ebfe892c139cdb68d747eea369d8588 Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@koprulu.sector>
Date: Thu, 2 Feb 2023 21:08:25 +0000
Subject: gentoo auto-resync : 02:02:2023 - 21:08:25

---
 app-emulation/uxn/uxn-0_p20230201.ebuild | 52 ++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 app-emulation/uxn/uxn-0_p20230201.ebuild

(limited to 'app-emulation/uxn/uxn-0_p20230201.ebuild')

diff --git a/app-emulation/uxn/uxn-0_p20230201.ebuild b/app-emulation/uxn/uxn-0_p20230201.ebuild
new file mode 100644
index 000000000000..1a4ba33c7ae1
--- /dev/null
+++ b/app-emulation/uxn/uxn-0_p20230201.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+[[ ${PV} == *_p20230201 ]] && COMMIT=0dcc3b4c2e12bf2a61e682e9168e8bdb469caae0
+
+inherit toolchain-funcs
+
+DESCRIPTION="An assembler and emulator for the Uxn stack-machine, written in ANSI C"
+HOMEPAGE="https://wiki.xxiivv.com/site/uxn.html
+	https://git.sr.ht/~rabbits/uxn/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.sr.ht/~rabbits/uxn.git"
+else
+	SRC_URI="https://git.sr.ht/~rabbits/uxn/archive/${COMMIT}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}"/${PN}-${COMMIT}
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="media-libs/libsdl2:="
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/uxn-build.sh.patch )
+
+src_compile() {
+	CC="$(tc-getCC)" CFLAGS="${CFLAGS} ${LDFLAGS}" ./build.sh --no-run ||
+		die "build failed"
+
+	local f
+	for f in ./projects/{examples/*,software,utils}/*.tal ; do
+		./bin/uxnasm "${f}" "$(dirname "${f}")"/"$(basename "${f}" .tal)".rom ||
+			die "failed to assemble ${f}"
+	done
+}
+
+src_install() {
+	exeinto /usr/bin
+	doexe bin/uxn*
+
+	insinto /usr/share/uxn
+	doins bin/*.rom
+	doins -r projects
+
+	einstalldocs
+}
-- 
cgit v1.2.3