From feb0daf81d888e9160f9f94502de09b66f2a63fd Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sun, 21 Jun 2020 17:50:24 +0100
Subject: gentoo resync : 21.06.2020

---
 app-emulation/skopeo/skopeo-1.1.0.ebuild | 52 ++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 app-emulation/skopeo/skopeo-1.1.0.ebuild

(limited to 'app-emulation/skopeo/skopeo-1.1.0.ebuild')

diff --git a/app-emulation/skopeo/skopeo-1.1.0.ebuild b/app-emulation/skopeo/skopeo-1.1.0.ebuild
new file mode 100644
index 000000000000..80f88e4f1c14
--- /dev/null
+++ b/app-emulation/skopeo/skopeo-1.1.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+COMMIT=63085f5bef1131aa9ec0907a5c8d66b67de7c4b2
+inherit go-module bash-completion-r1
+
+DESCRIPTION="Command line utility foroperations on container images and image repositories"
+HOMEPAGE="https://github.com/containers/skopeo"
+SRC_URI="https://github.com/containers/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="btrfs"
+
+COMMON_DEPEND=">=app-crypt/gpgme-1.5.5:=
+	>=dev-libs/libassuan-2.4.3:=
+	dev-libs/libgpg-error:=
+	btrfs? ( >=sys-fs/btrfs-progs-4.0.1 )
+	>=sys-fs/lvm2-2.02.145:="
+DEPEND="${COMMON_DEPEND}
+	dev-go/go-md2man"
+RDEPEND="${COMMON_DEPEND}"
+
+RESTRICT="test"
+
+src_compile() {
+	local BUILDTAGS
+	BUILDTAGS="containers_image_ostree_stub $(usex btrfs "" exclude_graphdriver_btrfs)"
+	set -- go build -mod=vendor -ldflags "-X main.gitCommit=${COMMIT}" \
+		-gcflags "${GOGCFLAGS}" -tags "${BUILDTAGS}" \
+		-o skopeo ./cmd/skopeo
+	echo "$@"
+	"$@" || die
+	cd docs || die
+	for f in *.1.md; do
+		go-md2man -in ${f} -out ${f%%.md} || die
+	done
+}
+
+src_install() {
+	dobin skopeo
+	doman docs/*.1
+	dobashcomp completions/bash/skopeo
+	insinto /etc/containers
+	newins default-policy.json policy.json
+	insinto /etc/containers/registries.d
+	doins default.yaml
+	keepdir /var/lib/atomic/sigstore
+	einstalldocs
+}
-- 
cgit v1.2.3