From b7b97785ebbb2f11d24d14dab8b81ed274f4ce6a Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Tue, 19 Mar 2019 11:37:34 +0000
Subject: gentoo resync : 19.03.2019

---
 app-emulation/skopeo/skopeo-0.1.35.ebuild | 54 +++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 app-emulation/skopeo/skopeo-0.1.35.ebuild

(limited to 'app-emulation/skopeo/skopeo-0.1.35.ebuild')

diff --git a/app-emulation/skopeo/skopeo-0.1.35.ebuild b/app-emulation/skopeo/skopeo-0.1.35.ebuild
new file mode 100644
index 000000000000..6a50ae5982c5
--- /dev/null
+++ b/app-emulation/skopeo/skopeo-0.1.35.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+EGO_PN=github.com/containers/skopeo
+COMMIT=404c5bd
+inherit golang-vcs-snapshot bash-completion-r1
+
+DESCRIPTION="Command line utility foroperations on container images and image repositories"
+HOMEPAGE="https://github.com/containers/skopeo"
+SRC_URI="https://github.com/containers/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+COMMON_DEPEND=">=app-crypt/gpgme-1.5.5:=
+	>=dev-libs/libassuan-2.4.3
+	>=sys-fs/btrfs-progs-4.0.1
+	>=sys-fs/lvm2-2.02.145"
+DEPEND="${COMMON_DEPEND}
+	dev-go/go-md2man"
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/${P}/src/${EGO_PN}"
+
+RESTRICT="test"
+
+src_compile() {
+	local BUILDTAGS="containers_image_ostree_stub"
+	set -- env -u GOCACHE -u XDG_CACHE_HOME GOPATH="${WORKDIR}/${P}" \
+		go build -ldflags "-X main.gitCommit=${COMMIT}" \
+		-gcflags "${GOGCFLAGS}" -tags "${BUILDTAGS}" \
+		-o skopeo ./cmd/skopeo
+	echo "$@"
+	"$@" || die
+	cd docs || die
+	for f in *.1.md; do
+		go-md2man -in ${f} -out ${f%%.md} || die
+	done
+}
+
+src_install() {
+	dobin skopeo
+	doman docs/*.1
+	dobashcomp completions/bash/skopeo
+	insinto /etc/containers
+	newins default-policy.json policy.json
+	insinto /etc/containers/registries.d
+	doins default.yaml
+	keepdir /var/lib/atomic/sigstore
+	einstalldocs
+}
-- 
cgit v1.2.3