From 67f76a858f1ac826bd8a550d756d9ec6e340ed4f Mon Sep 17 00:00:00 2001
From: V3n3RiX <venerix@redcorelinux.org>
Date: Sat, 27 Jan 2018 18:07:28 +0000
Subject: gentoo resync : 27.01.2018

---
 app-emulation/punes/punes-0.102.ebuild | 53 ++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 app-emulation/punes/punes-0.102.ebuild

(limited to 'app-emulation/punes/punes-0.102.ebuild')

diff --git a/app-emulation/punes/punes-0.102.ebuild b/app-emulation/punes/punes-0.102.ebuild
new file mode 100644
index 000000000000..cb13a8549234
--- /dev/null
+++ b/app-emulation/punes/punes-0.102.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools xdg-utils
+
+DESCRIPTION="Nintendo Entertainment System (NES) emulator"
+HOMEPAGE="https://github.com/punesemu/puNES"
+SRC_URI="https://github.com/punesemu/puNES/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cg"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	cg? ( media-gfx/nvidia-cg-toolkit )
+	media-libs/alsa-lib
+	media-libs/libsdl[opengl]
+	virtual/opengl"
+
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig"
+
+S="${WORKDIR}/puNES-${PV}"
+
+src_prepare() {
+	default
+
+	sed -i "/update-desktop-database/d" misc/Makefile.am || die
+	eautoreconf
+	# FIXME why eautoreconf can't handle this?
+	cd "src/extra/lib7zip-1.6.5" || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-qt5 \
+		$(use_with cg opengl-nvidia-cg)
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3